[gentoo-commits] repo/gentoo:master commit in: media-libs/fdk-aac/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     3d18db25b4e5e5fed5f7525fdf55e800884489b3
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 28 18:03:51 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Apr 28 18:04:09 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d18db25

media-libs/fdk-aac: bump to 2.0.2

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-libs/fdk-aac/Manifest             |  1 +
 media-libs/fdk-aac/fdk-aac-2.0.2.ebuild | 56 +++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/media-libs/fdk-aac/Manifest b/media-libs/fdk-aac/Manifest
index 7332f9fe8b3..7ce07ae0274 100644
--- a/media-libs/fdk-aac/Manifest
+++ b/media-libs/fdk-aac/Manifest
@@ -1 +1,2 @@
 DIST fdk-aac-2.0.1.tar.gz 2865456 BLAKE2B 79c66956b3c43138fb34448398cf104a021757332b2af6d4493bce8c4f9dfdf97a38d1f00c3f1a3f91ffb3b2ce2bb0bdc982e3f92a1ffe7e5f0d1c2f0ef8ca99 SHA512 08209bbd060edafe7b607c9e1394cd03df4f98df6f32b4be21d34d1ab491a7447ed592785546c040126767bd31980121ca6a31aba06eaf90558b14228e302d82
+DIST fdk-aac-2.0.2.tar.gz 2886434 BLAKE2B f9917cf8ded3e4165048b27211c5985b4fe174d1ac815a7bc4afad88e059f3a89a24f88ad20633becdba9cb91717b9d4bf44781368c436e35002061b1644eb64 SHA512 8e5a7992869a7e649bee6d41bf7c6e408cec7ba1931a6cd7a9ad8a01e6ac49bd299ddd147b18823e8ee379ce7c6373d7f5a94f0f859ed973a30c61eccd53fa7e

diff --git a/media-libs/fdk-aac/fdk-aac-2.0.2.ebuild b/media-libs/fdk-aac/fdk-aac-2.0.2.ebuild
new file mode 100644
index 00000000000..01bbf0f0867
--- /dev/null
+++ b/media-libs/fdk-aac/fdk-aac-2.0.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mstorsjo/${PN}.git"
+	[[ ${PV%9999} != "" ]] && EGIT_BRANCH="release/${PV%.9999}"
+	inherit autotools git-r3
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~x64-macos"
+	if [[ ${PV%_p*} != ${PV} ]]; then # Gentoo snapshot
+		SRC_URI="mirror://gentoo/${P}.tar.xz"
+	else # Official release
+		SRC_URI="mirror://sourceforge/opencore-amr/${P}.tar.gz"
+	fi
+fi
+
+DESCRIPTION="Fraunhofer AAC codec library"
+HOMEPAGE="https://sourceforge.net/projects/opencore-amr/"
+LICENSE="FraunhoferFDK"
+# subslot == N where N is libfdk-aac.so.N
+SLOT="0/2"
+
+IUSE="static-libs examples"
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable examples example)
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use examples; then
+		mv "${ED}/usr/bin/"{,fdk-}aac-enc || die
+	fi
+
+	# package provides .pc files
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	use examples && einfo "aac-enc was renamed to fdk-aac-enc to prevent file collision with other packages"
+}