[gentoo-commits] repo/gentoo:master commit in: app-cdr/dolphin-plugins-mountiso/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     52e5719bcc980f8d5fc2839408543caf906d5d79
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 24 10:05:07 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Apr 24 13:46:37 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=52e5719b

app-cdr/dolphin-plugins-mountiso: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-cdr/dolphin-plugins-mountiso/Manifest          |  1 +
 .../dolphin-plugins-mountiso-21.04.0.ebuild        | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index 5fc632221dd..dd4d1ef6228 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-20.12.3.tar.xz 239340 BLAKE2B 141e5d2bb6190edaef98cec2a271e41b916966118300d69f4eb5e7da15e51730476f23a20312b76fca0fc1490501e83528b4f0cb62f9f6c64e4caf5ac5b2cd37 SHA512 1d5303e92d912bc80c5260263b081205d36372f1f15205ebd3e705697a114f8481edd1ad31004d7906c3088d43a74cb1e33dac6e1196c247e702a544d67db11b
+DIST dolphin-plugins-21.04.0.tar.xz 242608 BLAKE2B c12366f9a0d661e79b968ce375e2ea46dd8d90f322691755dc238d4dd08d07f6527711aa117fead2a3714d7f97c508e53c5ecd87a69c23c397e44033669fe5b1 SHA512 9f093133eba93615392a117f8184177f06bb117d4a3ad4691025ef26e4d83e251f966c157ae107f52447c78bf600ab586a175f57a02f78fec8e620aa5462138d

diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.04.0.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.04.0.ebuild
new file mode 100644
index 00000000000..27a4b3f28f9
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.04.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.80.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}