[gentoo-commits] proj/sci:master commit in: sci-biology/abyss/

["Martin Mokrejs" <mmokrejs@fold.natur.cuni.cz>]

commit:     6c252245a4ab18f5d211723f9078682dfa06bd00
Author:     Martin Mokrejs <mmokrejs <AT> gmail <DOT> com>
AuthorDate: Thu Apr 22 07:23:16 2021 +0000
Commit:     Martin Mokrejs <mmokrejs <AT> fold <DOT> natur <DOT> cuni <DOT> cz>
CommitDate: Thu Apr 22 07:23:16 2021 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=6c252245

sci-biology/abyss: add 2.3.1 release but keep patches

The PathConsensus crash fixes were not included by upstream,
keep them.

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Martin Mokrejs <mmokrejs <AT> gmail.com>

 sci-biology/abyss/abyss-2.3.1.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/sci-biology/abyss/abyss-2.3.1.ebuild b/sci-biology/abyss/abyss-2.3.1.ebuild
new file mode 100644
index 000000000..d9134813b
--- /dev/null
+++ b/sci-biology/abyss/abyss-2.3.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Assembly By Short Sequences - a de novo, parallel, paired-end sequence assembler"
+HOMEPAGE="http://www.bcgsc.ca/platform/bioinfo/software/abyss/"
+SRC_URI="https://github.com/bcgsc/abyss/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+mpi openmp misc-haskell"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-cpp/sparsehash
+	dev-libs/boost:=
+	misc-haskell? (
+		dev-libs/gmp:0=
+		dev-libs/libffi:0=
+	)
+	mpi? ( sys-cluster/openmpi )"
+DEPEND="${RDEPEND}
+	misc-haskell? (
+		dev-lang/ghc
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.2.5-PathConsensus-assert.patch
+		"${FILESDIR}"/${PN}-2.2.5-ContigProperties.h.patch
+	)
+
+# todo: --enable-maxk=N configure option
+# todo: fix automagic mpi toggling
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/-Werror//" configure.ac || die #365195
+	sed -i -e "/dist_pkgdoc_DATA/d" Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	# disable building haskell tool Misc/samtobreak
+	# unless request by user: bug #534412
+	use misc-haskell || export ac_cv_prog_ac_ct_GHC=
+
+	econf $(use_enable openmp) --enable-maxk=256
+}