[gentoo-commits] repo/gentoo:master commit in: x11-misc/tabbed/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     59a1c64b51f537094c44481d16e70b66e38f47c3
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 21 20:22:23 2021 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Wed Apr 21 20:23:36 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=59a1c64b

x11-misc/tabbed: bump to EAPI=7

Bug: https://bugs.gentoo.org/780909
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 x11-misc/tabbed/tabbed-0.6-r1.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/x11-misc/tabbed/tabbed-0.6-r1.ebuild b/x11-misc/tabbed/tabbed-0.6-r1.ebuild
new file mode 100644
index 00000000000..df9afe56b40
--- /dev/null
+++ b/x11-misc/tabbed/tabbed-0.6-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="Simple generic tabbed fronted to xembed aware applications"
+HOMEPAGE="https://tools.suckless.org/tabbed"
+SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/libX11"
+DEPEND="
+	x11-base/xorg-proto
+	${RDEPEND}
+"
+
+src_prepare() {
+	default
+	sed config.mk \
+		-e '/^CC/d' \
+		-e 's|/usr/local|/usr|g' \
+		-e 's|^CFLAGS.*|CFLAGS += -std=c99 -pedantic -Wall $(INCS) $(CPPFLAGS)|g' \
+		-e 's|^LDFLAGS.*|LDFLAGS += $(CFLAGS) $(LIBS)|g' \
+		-e 's|^LIBS.*|LIBS = -lX11|g' \
+		-e 's|{|(|g;s|}|)|g' \
+		-i || die
+
+	sed Makefile \
+		-e 's|{|(|g;s|}|)|g' \
+		-e '/^[[:space:]]*@echo/d' \
+		-e 's|^	@|	|g' \
+		-i || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	emake CC=$(tc-getCC)
+}
+src_install() {
+	default
+	save_config config.h
+}