[gentoo-commits] repo/gentoo:master commit in: media-radio/tucnak/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     cfda22f66a3ca5f06189e20d7b0fd72ae8f43817
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 17 18:09:13 2021 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Sat Apr 17 18:09:13 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cfda22f6

media-radio/tucnak: Version bump

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/tucnak/Manifest           |  1 +
 media-radio/tucnak/tucnak-4.27.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 0cbd808c324..877fed63422 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.25.tar.gz 3588485 BLAKE2B ade2db19e3be9981d4c3813306e347f47df4e89d62a9b2c382f4b5ac04700850af40e63d8b4b13d7f7ae59f47c864c3af4a8fd7eb572919e4163b106da5d9ce8 SHA512 b9666877f322e3142dae6d95e65b7b1da7e14eac5517d11ae108bf96715205558697a80bb40faa20bf89a01385c30869c48aa8af197dd2c206b4bc8f8b5859b9
+DIST tucnak-4.27.tar.gz 3589057 BLAKE2B df089401ce82d6b956e2be8f3a069ba3db5af11a0eb7e5cc4b6e9aeeca0bbaa8a82a22f16ad02d5ed89144415d491f8941add457eb61ef9b3fd62e518068da4e SHA512 a112cc02259c3ae05404bf2fb17e56902fe68681be418a89b53eb54e067671236f0764d717334b89949355499f0119db46b1afb8329245ac6ce5db8d514a55e2

diff --git a/media-radio/tucnak/tucnak-4.27.ebuild b/media-radio/tucnak/tucnak-4.27.ebuild
new file mode 100644
index 00000000000..74d1b35b9c8
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.27.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic multilib
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libzia
+	media-libs/libsndfile
+	>=media-libs/libsdl-1.2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}