[gentoo-commits] repo/gentoo:master commit in: net-mail/mailutils/files/, net-mail/mailutils/

["Eray Aslan" <eras@gentoo.org>]

commit:     b53245a868edbae2e47e15767cb7dddc73c36524
Author:     Eray Aslan <eras <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 17 09:04:39 2021 +0000
Commit:     Eray Aslan <eras <AT> gentoo <DOT> org>
CommitDate: Sat Apr 17 09:04:58 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b53245a8

net-mail/mailutils: fix big endian archs

also
 - fix HOMEPAGE
 - add missing endif

thanks to ernsteiswuerfel and Rolf Eike Beer

Closes: https://bugs.gentoo.org/670924
Closes: https://bugs.gentoo.org/727998
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Eray Aslan <eras <AT> gentoo.org>

 .../files/mailutils-3.12-fix-big-endians.patch     |  26 ++++
 .../files/mailutils-3.12-misssing-endif.patch      |  23 ++++
 net-mail/mailutils/mailutils-3.12-r1.ebuild        | 141 +++++++++++++++++++++
 3 files changed, 190 insertions(+)

diff --git a/net-mail/mailutils/files/mailutils-3.12-fix-big-endians.patch b/net-mail/mailutils/files/mailutils-3.12-fix-big-endians.patch
new file mode 100644
index 00000000000..5dd2f8f035d
--- /dev/null
+++ b/net-mail/mailutils/files/mailutils-3.12-fix-big-endians.patch
@@ -0,0 +1,26 @@
+From c0af3be2fcee73c1a61f58572ecef1ef3f385015 Mon Sep 17 00:00:00 2001
+From: Sergey Poznyakoff <gray@gnu.org>
+Date: Thu, 15 Apr 2021 08:37:29 +0300
+Subject: Bugfix in mimeview testsuite
+
+* mimeview/tests/bf.c (write_byte): Fix type of the character buffer.
+---
+ mimeview/tests/bf.c | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/mimeview/tests/bf.c b/mimeview/tests/bf.c
+index 6ccce848c..2e6b37e4a 100644
+--- a/mimeview/tests/bf.c
++++ b/mimeview/tests/bf.c
+@@ -68,7 +68,7 @@ write_string (FILE *fp, char *arg)
+ int
+ write_byte (FILE *fp, char *arg)
+ {
+-  int c;
++  char c;
+   if (strlen (arg) == 3
+       && (arg[0] == '\'' || arg[0] == '"'))
+     c = arg[1];
+-- 
+cgit v1.2.1
+

diff --git a/net-mail/mailutils/files/mailutils-3.12-misssing-endif.patch b/net-mail/mailutils/files/mailutils-3.12-misssing-endif.patch
new file mode 100644
index 00000000000..12d03af7b33
--- /dev/null
+++ b/net-mail/mailutils/files/mailutils-3.12-misssing-endif.patch
@@ -0,0 +1,23 @@
+From 4cc284cfb38306989694a7828e880f0cf6d0c4e0 Mon Sep 17 00:00:00 2001
+From: Sergey Poznyakoff <gray@gnu.org>
+Date: Thu, 15 Apr 2021 08:36:56 +0300
+Subject: Minor fix
+
+* include/mailutils/sys/streamtrans.h: Add missing #endif
+---
+ include/mailutils/sys/streamtrans.h | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git a/include/mailutils/sys/streamtrans.h b/include/mailutils/sys/streamtrans.h
+index 8a4727cee..c9c866013 100644
+--- a/include/mailutils/sys/streamtrans.h
++++ b/include/mailutils/sys/streamtrans.h
+@@ -25,3 +25,5 @@ struct _mu_streamtrans
+   struct _mu_stream base;      /* Superclass */
+   mu_stream_t transport;       /* Transport stream */
+ };
++
++#endif
+-- 
+cgit v1.2.1
+

diff --git a/net-mail/mailutils/mailutils-3.12-r1.ebuild b/net-mail/mailutils/mailutils-3.12-r1.ebuild
new file mode 100644
index 00000000000..89bc57c915a
--- /dev/null
+++ b/net-mail/mailutils/mailutils-3.12-r1.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools elisp-common eutils flag-o-matic python-single-r1 toolchain-funcs
+
+DESCRIPTION="A useful collection of mail servers, clients, and filters"
+HOMEPAGE="https://mailutils.org/"
+SRC_URI="mirror://gnu/mailutils/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos"
+IUSE="berkdb bidi +clients emacs gdbm sasl guile ipv6 kerberos kyotocabinet \
+	ldap mysql nls pam postgres python servers split-usr ssl static-libs +threads tcpd \
+	tokyocabinet"
+
+RDEPEND="!mail-client/nmh
+	!mail-filter/libsieve
+	!mail-client/mailx
+	!mail-client/nail
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+	dev-libs/libltdl:0
+	virtual/mta
+	berkdb? ( sys-libs/db:= )
+	bidi? ( dev-libs/fribidi )
+	emacs? ( >=app-editors/emacs-23.1:* )
+	gdbm? ( sys-libs/gdbm:= )
+	guile? ( dev-scheme/guile:12/2.2-1 )
+	kerberos? ( virtual/krb5 )
+	kyotocabinet? ( dev-db/kyotocabinet )
+	ldap? ( net-nds/openldap )
+	mysql? ( dev-db/mysql-connector-c )
+	nls? ( sys-devel/gettext )
+	pam? ( sys-libs/pam )
+	postgres? ( dev-db/postgresql:= )
+	python? ( ${PYTHON_DEPS} )
+	sasl? ( virtual/gsasl )
+	servers? ( virtual/libiconv dev-libs/libunistring )
+	ssl? ( net-libs/gnutls:= )
+	tcpd? ( sys-apps/tcp-wrappers )
+	tokyocabinet? ( dev-db/tokyocabinet )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	servers? ( tcpd ldap )"
+
+DOCS=( ABOUT-NLS AUTHORS COPYING COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO )
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.5-add-include.patch
+	"${FILESDIR}"/${P}-misssing-endif.patch
+	"${FILESDIR}"/${P}-fix-big-endians.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	if use mysql; then
+		sed -i -e /^INCLUDES/"s:$:$(mysql_config --include):" \
+			sql/Makefile.am || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	# maildir is the Gentoo default
+	econf \
+		MU_DEFAULT_SCHEME=maildir \
+		CURSES_LIBS="$($(tc-getPKG_CONFIG) --libs ncurses)" \
+		$(use_with berkdb berkeley-db) \
+		$(use_with bidi fribidi) \
+		$(use_enable ipv6) \
+		$(use_with gdbm) \
+		$(use_with sasl gsasl) \
+		$(use_with guile) \
+		$(use_with kerberos gssapi) \
+		$(use_with ldap) \
+		$(use_with mysql) \
+		$(use_enable nls) \
+		$(use_enable pam) \
+		$(use_with postgres) \
+		$(use_enable python) \
+		$(use_with ssl gnutls) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with tokyocabinet) \
+		$(use_with kyotocabinet) \
+		$(use_with tcpd tcp-wrappers) \
+		$(use_enable servers build-servers) \
+		$(use_with servers unistring ) \
+		$(use_enable clients build-clients) \
+		EMACS=$(usex emacs emacs no) \
+		--with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		--with-mail-spool=/var/spool/mail \
+		--with-readline \
+		--enable-sendmail \
+		--disable-debug
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	# bug 613112
+	newins "${FILESDIR}/mailutils.rc" mailutils.conf
+	keepdir /etc/mailutils.d/
+	insinto /etc/mailutils.d
+	doins "${FILESDIR}/mail"
+
+	if use python; then
+		python_optimize
+		if use static-libs; then
+			rm -r "${D}$(python_get_sitedir)/mailutils"/*.{a,la} || die
+		fi
+	fi
+
+	if use servers; then
+		newinitd "${FILESDIR}"/imap4d.initd imap4d
+		newinitd "${FILESDIR}"/pop3d.initd pop3d
+		newinitd "${FILESDIR}"/comsatd.initd comsatd
+	fi
+
+	# compatibility link
+	if use clients && use split-usr; then
+		dosym ../usr/bin/mail /bin/mail
+	fi
+
+	if ! use static-libs; then
+		find "${D}" -name "*.la" -delete || die
+	fi
+}