[gentoo-commits] repo/gentoo:master commit in: media-libs/gexiv2/

["Matt Turner" <mattst88@gentoo.org>]

commit:     857f1d6a1ef460789c27299e0feb2f266367dcbd
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 20:59:00 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 16 21:00:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=857f1d6a

media-libs/gexiv2: Version bump to 0.12.2

Closes: https://bugs.gentoo.org/775653
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-libs/gexiv2/Manifest             |  1 +
 media-libs/gexiv2/gexiv2-0.12.2.ebuild | 74 ++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-libs/gexiv2/Manifest b/media-libs/gexiv2/Manifest
index 81c2d8bcc74..95e84dc303d 100644
--- a/media-libs/gexiv2/Manifest
+++ b/media-libs/gexiv2/Manifest
@@ -1 +1,2 @@
 DIST gexiv2-0.12.1.tar.xz 372104 BLAKE2B e712bc8056e0e02d66ee831425776c26b65275db8f4cb4a526dbe9f00bddc473312f6c4c8e011906ca02ff256c00c7fe8d602acd64c787b05e13ad582ff8ebee SHA512 cbf83ea79eead9aab15ba760217fd6a1b55a5c60059f14f243327ad7d3c09d6a0528dbdb33a8ee235c76dac5aab0afa8b7d2ab4367fe9128a096dce5da19a68d
+DIST gexiv2-0.12.2.tar.xz 378428 BLAKE2B bb3fd6310cdb76f3e88bb31e018d78013bb626559b9e95bf59688601388cff10739c20c431fa9539c1d24c9045d2b3590a0f783a994d3b8966c4df12e9127f4e SHA512 850bf41f6180b0fdd050ab08da6e3bbd8d25ffc25a1f48e17a1d7a65771893cc79fba9cbd6718bf1754251ac4a4754983f0ab8f006a05f8c4a15085846d001a5

diff --git a/media-libs/gexiv2/gexiv2-0.12.2.ebuild b/media-libs/gexiv2/gexiv2-0.12.2.ebuild
new file mode 100644
index 00000000000..54ea8224ebf
--- /dev/null
+++ b/media-libs/gexiv2/gexiv2-0.12.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit meson python-r1 vala
+
+DESCRIPTION="GObject-based wrapper around the Exiv2 library"
+HOMEPAGE="https://wiki.gnome.org/Projects/gexiv2"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gexiv2.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://gnome/sources/${PN}/$(ver_cut 1-2)/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+LICENSE="LGPL-2.1+ GPL-2"
+SLOT="0"
+IUSE="gtk-doc +introspection python static-libs test +vala"
+REQUIRED_USE="
+	python? ( introspection ${PYTHON_REQUIRED_USE} )
+	test? ( python introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=media-gfx/exiv2-0.26:=
+	>=dev-libs/glib-2.46.0:2
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	python? ( ${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	test? ( media-gfx/exiv2[xmp] )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		-Dtools=false # requires vala, freshly promoted tool that some other distros don't ship yet either
+		# Prevents installation of python modules (uses install_data from meson
+		# which does not optimize the modules)
+		-Dpython2_girdir=no
+		-Dpython3_girdir=no
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi/overrides/
+		python_foreach_impl python_domodule GExiv2.py
+	fi
+}