[gentoo-commits] repo/gentoo:master commit in: net-libs/libgfbgraph/

["Matt Turner" <mattst88@gentoo.org>]

commit:     812dce69bb6e2068e6115ddfe4cb6e15f16d30a1
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 20:02:13 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 16 20:37:50 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=812dce69

net-libs/libgfbgraph: Version bump to 0.2.4

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-libs/libgfbgraph/Manifest                 |  1 +
 net-libs/libgfbgraph/libgfbgraph-0.2.4.ebuild | 52 +++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/net-libs/libgfbgraph/Manifest b/net-libs/libgfbgraph/Manifest
index ca3735e9733..1939f897f27 100644
--- a/net-libs/libgfbgraph/Manifest
+++ b/net-libs/libgfbgraph/Manifest
@@ -1 +1,2 @@
 DIST gfbgraph-0.2.3.tar.xz 270772 BLAKE2B 4e9e1d9ed5d0bc58d6b01f6d58d7d9dc8cddb28c09bc820927e242a7d6118aabc8e4d808050205cf2d516571c598a0dbc75e09588e64d53db1456d519d23b810 SHA512 4e03beb4172a591c7d1eb4cfac56009b0d25183168f73344d24ac47554334d1edf2c5087c523025cee5d565182a02dc7ef72adc66cff1e4ad53a1d0990d3afb8
+DIST gfbgraph-0.2.4.tar.xz 39520 BLAKE2B 71ce5a091b5ab7d27b7b5353ff76cb67c90a358371f1afe41a561bab195c7e01353854fbd28c3970c3179ded24daf41f7150f70b5efcb1c81aac89de9fed2c88 SHA512 e6d63e56f4d67b59b0abbfb9dfe3aad8b142023413246015a84078c76f631eaa6e9fa7eb5771f64156ea01e160eb07b17783059e449036b372b4bcb26751ff68

diff --git a/net-libs/libgfbgraph/libgfbgraph-0.2.4.ebuild b/net-libs/libgfbgraph/libgfbgraph-0.2.4.ebuild
new file mode 100644
index 00000000000..1032f0a26ad
--- /dev/null
+++ b/net-libs/libgfbgraph/libgfbgraph-0.2.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GNOME_ORG_MODULE="gfbgraph"
+GNOME2_EAUTORECONF="yes"
+
+inherit gnome2
+
+DESCRIPTION="A GObject library for Facebook Graph API"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libgfbgraph/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.2"
+KEYWORDS="amd64 ~arm64 x86"
+IUSE="+introspection"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib[introspection?]
+	net-libs/libsoup:2.4[introspection?]
+	net-libs/gnome-online-accounts
+	net-libs/rest:0.7[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-util/gtk-doc-am-1.14
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Test requires a credentials.ini file.
+	# https://gitlab.gnome.org/GNOME/libgfbgraph/-/issues/7#note_802926
+	sed -i -e 's:TESTS = gtestutils:TESTS =:' tests/Makefile.am || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable introspection)
+}
+
+src_install() {
+	gnome2_src_install
+	# Remove files installed in the wrong place
+	# Also, already done by portage
+	# https://bugzilla.gnome.org/show_bug.cgi?id=752581
+	rm -rf "${ED}"/usr/doc
+}