[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgdata/

["Matt Turner" <mattst88@gentoo.org>]

commit:     f79495c93ce4f6abd0bf07b4395e8f907f487244
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 12 21:38:09 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Apr 12 21:59:28 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f79495c9

dev-libs/libgdata: Version bump to 0.18.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libgdata/Manifest               |  1 +
 dev-libs/libgdata/libgdata-0.18.1.ebuild | 64 ++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-libs/libgdata/Manifest b/dev-libs/libgdata/Manifest
index cde43ae21df..beb10551742 100644
--- a/dev-libs/libgdata/Manifest
+++ b/dev-libs/libgdata/Manifest
@@ -1,2 +1,3 @@
 DIST libgdata-0.17.12.tar.xz 845420 BLAKE2B 636ff5ba7df48f671cdb5da09c011f620619051e30470bb3ebb400f8c093e89885e0c3c7ac54e569cff2c350bd08f7e346f1529c07c41f570b7255002fc69c44 SHA512 22571c9b0cecbaf617fc8fa43a312bba4eaf36267264546f55c9c9067514cc6ae1db755536c7413427ebf6121115512dcab4201549c128fb1a25afe75a3daa2b
 DIST libgdata-0.17.13.tar.xz 849888 BLAKE2B a364f6175828dcf6d870ddf8489da3703b987587639675ed5cbe851de8761d918da9ef91531d2b992ef5188b51f00f4bc13c3ce3b36afe6d07c4e162a93b2889 SHA512 b074097bd3cc78951638f0d726a948c9ba994c64c85c0cfe713c3d87419a9a96b66688bde88732dfb529325dca2b8251bd161337532bffaf9564f7f5819b9343
+DIST libgdata-0.18.1.tar.xz 851584 BLAKE2B 860cc42c4d0bdbdd6ca1a1001ec7ea5acc26dd1339052365554123e6524fddce65704a11614c8a081eb3eef10395fb1b4d2dfd3cf942dd1ae3556507af4c7c52 SHA512 15ff708760ca5023b692fd565c26a7c3acf035073534c0cd3f1f90e46ee0c60d14dedf360d3ac146d37135e200d9c2bc4b657e81468d0efde4821a9219875b98

diff --git a/dev-libs/libgdata/libgdata-0.18.1.ebuild b/dev-libs/libgdata/libgdata-0.18.1.ebuild
new file mode 100644
index 00000000000..4b2bee552d9
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.18.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/json-glib-0.15[introspection?]
+	>=dev-libs/libxml2-2:2
+	>=net-libs/libsoup-2.55.90:2.4[introspection?,vala?]
+	crypt? ( app-crypt/gcr:= )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:=[introspection?,vala?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( >=net-libs/uhttpmock-0.5.0
+		>=x11-libs/gdk-pixbuf-2.14:2
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+	# Don't waste time building a couple small demos that aren't installed
+	sed -i -e '/subdir.*demos/d' meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgtk=disabled # only for demos
+		$(meson_feature crypt gnome)
+		$(meson_feature gnome-online-accounts goa)
+		-Doauth1=disabled
+		$(meson_use test always_build_tests)
+		-Dinstalled_tests=false
+		-Dman=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}