[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     a46a823ba69190b1857b74c2e63a896e17486357
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 12 15:47:20 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Apr 12 15:48:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a46a823b

sys-kernel/gentoo-kernel-bin: bump to 5.11.13 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.11.13-r1.ebuild            | 115 +++++++++++++++++++++
 2 files changed, 116 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5aa08abd172..01007604979 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -65,6 +65,7 @@ DIST gentoo-kernel-5.11.12-1.amd64.xpak 64702763 BLAKE2B 2e94dc30ef2ad0728db804b
 DIST gentoo-kernel-5.11.12-1.arm64.xpak 59788658 BLAKE2B 826a575adb837ec51cd1169e5f56218b24a3544621ca56f222686ee982141adab992f555f53eb98f9099a445aa5693c238dfe11c55895bf3f2fbe1b620296ac0 SHA512 47f0072f95e07197248e90d70fefae33f6c2248efa8d5546a0aea27229dc1bdd5c4eaf9263f8a3da24a16b56d2d25bbc86f905258498fd8332470f255a1df3ac
 DIST gentoo-kernel-5.11.12-1.x86.xpak 57631535 BLAKE2B 487b8298e9053061d18dd7e1d4e7a68f7ef9aee0762b48779d3c28ee5fc76a620941c449cb3aca38623f385e8aa2ca0a2992820b61a33bbb2233b4dec2ea49c8 SHA512 4afde6eb532978e59665b213280aa8cddabe440257f10c53357ef00a7ce576daf89e3a42b8e73278bd8a20561977e3c23b487ca13c165ac61aca1b4e1024f90d
 DIST gentoo-kernel-5.11.13-1.amd64.xpak 64685029 BLAKE2B 7d6794c5fd15434d2ad93d36678476e4a6aa3ad9ff77140a0bc8d74b0c87155898e8f1f76dfd40f72c878d9ddca7b7f1a9f0d4be2a600c5e2c18a77a3439e9d5 SHA512 d8c0fb975ee35e6d71b3b255800179805c9e70bfa7ef5299a38145c6cfd4f60720281c70f2d16a409a10c4ee6c6f26ac2e0c3151b114ced91c747371b59885b0
+DIST gentoo-kernel-5.11.13-1.arm64.xpak 59816443 BLAKE2B f3bd4b929cd103f95b91f0c0f28f324f8e316e1cc4b310742d159b8dbdb6c288d9424984e0859873924ac7eb34f12278b2086ad48fbf11da955f0b390dfda619 SHA512 6aae6cd29857eb897a167e359f9628692803bb75a0a1f235468a1b95e9c2f3d9525f33d6673b5c12edb5d9feba29210a79d8030d151a5b7260119a81eef57e1d
 DIST gentoo-kernel-5.11.13-1.x86.xpak 57618749 BLAKE2B d7e3d71d8eb7c35b4f86bb95cdf945f4fa7eadd0b87e380ef37f3b63385a15566246e91f12bffc0a7e3e42285f702cd99387fd9b7e11cb59fe3bc2a9da83f160 SHA512 51450b58469fdd8b663ee7b997b392232c658281fd243c2508f8feb190a74f5ab952b1041e64a9b4204cc1e08fe328f06262ca46966e16a0f0c962b389254fc1
 DIST gentoo-kernel-5.11.5-1.amd64.xpak 64924579 BLAKE2B b4484bb69d8355f63acecadac5a604ab57f61ae87a4341cba16c6b3cdc35d19c64c6d8042fedc69aa1272c151d09ba5957b9b26f2a6ab067a46451fd0a928b9b SHA512 218d649adc456f13055e7ec7ce3de1ead2cfdcc41d6d5d023de67dcc7a21679154dfe057dcf72592ab7a7315a8cf1a4d7a96f7904c21f0f8e219f3a277dae21f
 DIST gentoo-kernel-5.11.5-1.arm64.xpak 59869818 BLAKE2B 26d4431d1e9e3dd58f1d352ab872cf2749d64ae768a114d42cf1bf3ac342c9792dfa19ccd1bf502ea26ee99a0bb00e75783b2958726d5073d8f69c3f66e29a9c SHA512 ea64669b86cb1a3c86f92016f8a9838eabf1328c9a996084c8e8226b736d526b7d246f42d24ff9d07d2d0606cc0db914251b7007caa74080a482c0bcdd4a0bc6

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.13-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.13-r1.ebuild
new file mode 100644
index 00000000000..2760e617c65
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.13-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}