[gentoo-commits] repo/proj/emacs:master commit in: app-xemacs/ebuild-mode/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     380e8fc9c854b0de68974d66c3f0dc18fc2c383f
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Wed Apr  7 15:14:21 2021 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Wed Apr  7 15:14:21 2021 +0000
URL:        https://gitweb.gentoo.org/repo/proj/emacs.git/commit/?id=380e8fc9

app-xemacs/ebuild-mode: Initial import

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild | 42 ++++++++++++++++++++++++++
 app-xemacs/ebuild-mode/metadata.xml            | 15 +++++++++
 2 files changed, 57 insertions(+)

diff --git a/app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild b/app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild
new file mode 100644
index 0000000..ed3a18b
--- /dev/null
+++ b/app-xemacs/ebuild-mode/ebuild-mode-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/ebuild-mode.git"
+EGIT_BRANCH="master"
+EGIT_CHECKOUT_DIR="${WORKDIR}/${PN}"
+
+inherit git-r3
+
+DESCRIPTION="Emacs modes for editing ebuilds and other Gentoo specific files"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+RDEPEND=">=app-editors/xemacs-21.4.20-r5
+	app-xemacs/sh-script"
+BDEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	local XEMACS="${EPREFIX}/usr/bin/xemacs"
+
+	"${XEMACS}" -batch -q --no-site-file \
+		-eval "(add-to-list 'load-path \".\")" \
+		-f batch-byte-compile \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+
+	"${XEMACS}" -batch -q --no-site-file \
+		-eval "(setq autoload-package-name \"${PN}\")" \
+		-eval "(setq generated-autoload-file \"${S}/auto-autoloads.el\")" \
+		-l autoload -f batch-update-autoloads \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+}
+
+src_install() {
+	insinto /usr/share/xemacs/site-packages/lisp/${PN}
+	doins *.el *.elc
+}

diff --git a/app-xemacs/ebuild-mode/metadata.xml b/app-xemacs/ebuild-mode/metadata.xml
new file mode 100644
index 0000000..f476c13
--- /dev/null
+++ b/app-xemacs/ebuild-mode/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>xemacs@gentoo.org</email>
+    <name>Gentoo XEmacs project</name>
+  </maintainer>
+  <stabilize-allarches/>
+  <upstream>
+    <maintainer status="active">
+      <email>emacs@gentoo.org</email>
+      <name>Gentoo Emacs project</name>
+    </maintainer>
+  </upstream>
+</pkgmetadata>