[gentoo-commits] repo/gentoo:master commit in: games-arcade/jardinains/, games-arcade/jardinains/files/

[gentoo-commits] repo/gentoo:master commit in: games-arcade/jardinains/, games-arcade/jardinains/files/

[Sam James]

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1: Type: text/plain; charset=UTF-8, Size: 4042 bytes --]

commit:     b469e5f06a6bd3fbcbc5c234ba671e829d775f18
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Apr  7 09:01:59 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Apr  7 09:02:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b469e5f0

games-arcade/jardinains: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-arcade/jardinains/files/strings-pt.patch     |  4 +-
 ...ains-2.0-r1.ebuild => jardinains-2.0-r2.ebuild} | 58 +++++++++++++---------
 2 files changed, 36 insertions(+), 26 deletions(-)

diff --git a/games-arcade/jardinains/files/strings-pt.patch b/games-arcade/jardinains/files/strings-pt.patch
index 246017a3f5b..f4dfe3f5d46 100644
--- a/games-arcade/jardinains/files/strings-pt.patch
+++ b/games-arcade/jardinains/files/strings-pt.patch
@@ -1,5 +1,5 @@
---- data/strings.xml	2006-11-11 23:45:28.000000000 +0000
-+++ data/strings.xml	2007-02-02 14:14:14.000000000 +0000
+--- a/data/strings.xml
++++ b/data/strings.xml
 @@ -35,5 +35,5 @@
  		<es>Español</es>
  		<it>Italiano</it>

diff --git a/games-arcade/jardinains/jardinains-2.0-r1.ebuild b/games-arcade/jardinains/jardinains-2.0-r2.ebuild
similarity index 53%
rename from games-arcade/jardinains/jardinains-2.0-r1.ebuild
rename to games-arcade/jardinains/jardinains-2.0-r2.ebuild
index e98d0da5f03..177944be5b6 100644
--- a/games-arcade/jardinains/jardinains-2.0-r1.ebuild
+++ b/games-arcade/jardinains/jardinains-2.0-r2.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils games
+EAPI=7
+
+inherit desktop wrapper
 
 DESCRIPTION="Arkanoid with Gnomes"
 HOMEPAGE="http://www.jardinains2.com"
@@ -11,20 +12,26 @@ SRC_URI="mirror://gentoo/JN2_1_FREE_LIN.tar.gz"
 LICENSE="jardinains"
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
-IUSE=""
+
 RESTRICT="strip"
-QA_EXECSTACK="${GAMES_PREFIX_OPT:1}/jardinains/jardinains"
+QA_EXECSTACK="opt/jardinains/jardinains"
 
-DEPEND=""
-RDEPEND="sys-libs/libstdc++-v3:5
-	amd64? ( sys-libs/libstdc++-v3:5[multilib] )
+RDEPEND="
+	acct-group/gamestat
+	sys-libs/libstdc++-v3:5
 	>=virtual/opengl-7.0-r1[abi_x86_32(-)]
 	>=virtual/glu-9.0-r1[abi_x86_32(-)]
 	>=x11-libs/libX11-1.6.2[abi_x86_32(-)]
-	>=x11-libs/libXxf86vm-1.1.3[abi_x86_32(-)]"
+	>=x11-libs/libXxf86vm-1.1.3[abi_x86_32(-)]
+	amd64? ( sys-libs/libstdc++-v3:5[multilib] )
+"
+
+dir=opt/${PN}
+QA_PREBUILT="${dir}/${PN}"
 
-dir=${GAMES_PREFIX_OPT}/${PN}
-QA_PREBUILT="${dir:1}/${PN}"
+PATCHES=(
+	"${FILESDIR}"/strings-pt.patch
+)
 
 src_unpack() {
 	unpack JN2_1_FREE_LIN.tar.gz
@@ -33,30 +40,33 @@ src_unpack() {
 }
 
 src_prepare() {
+	default
+
 	# clean Mac fork files (bug #295782)
-	find . -type f -name "._*" -exec rm -f '{}' +
-	epatch "${FILESDIR}"/strings-pt.patch
+	find . -type f -name "._*" -exec rm -f '{}' + || die
 }
 
 src_install() {
-	exeinto "${dir}"
+	exeinto ${dir}
 	doexe jardinains
-	insinto "${dir}"
-	doins -r LICENSE.txt data help
 
-	games_make_wrapper jardinains ./jardinains "${dir}" "${dir}"
+	insinto ${dir}
+	doins -r LICENSE.txt data help
 
+	make_wrapper jardinains ./jardinains "${dir}" "${dir}"
 	make_desktop_entry jardinains "Jardinains 2"
-	touch "${D}${dir}/data/prefs.xml"
-	prepgamesdirs
-	chmod g+rw "${D}${dir}/data/prefs.xml"
-	chmod -R g+rw "${D}${dir}/data/players"
+	touch "${ED}"/${dir}/data/prefs.xml || die
+
+	chmod g+rw "${ED}"/${dir}/data/prefs.xml || die
+	chmod -R g+rw "${ED}"/${dir}/data/players || die
+
+	fperms -R 660 /opt/${PN}/data
+	fowners -R root:gamestat /opt/${PN}/data
+	fperms g+s /opt/${PN}/${PN}
 }
 
 pkg_postinst() {
-	games_pkg_postinst
 	elog "Due to the way this software is designed all user preferences for"
 	elog "graphics, audio and other in game data are shared among all users"
-	elog "of the computer. For that reason some files in the installation"
-	elog "folder are writable by any user in the games group."
+	elog "of the computer."
 }