[gentoo-commits] repo/gentoo:master commit in: games-puzzle/bff-or-die/

[gentoo-commits] repo/gentoo:master commit in: games-puzzle/bff-or-die/

[James Le Cuirot]

commit:     151ac68b15b07f6e6a86bbfa1a858bed372057b7
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  4 19:42:26 2020 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sat Jul  4 19:42:26 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=151ac68b

games-puzzle/bff-or-die: New package

Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 games-puzzle/bff-or-die/Manifest                   |  1 +
 games-puzzle/bff-or-die/bff-or-die-20200614.ebuild | 51 ++++++++++++++++++++++
 games-puzzle/bff-or-die/metadata.xml               |  8 ++++
 3 files changed, 60 insertions(+)

diff --git a/games-puzzle/bff-or-die/Manifest b/games-puzzle/bff-or-die/Manifest
new file mode 100644
index 00000000000..bdc152a2bcc
--- /dev/null
+++ b/games-puzzle/bff-or-die/Manifest
@@ -0,0 +1 @@
+DIST BffOrDie_Linux.zip 194773335 BLAKE2B a32d6b26e446d84110db13340d527ad1ccc423ddb1dfcdacabaf80c0b326f7c7c3d8315b26cc3a8cf4c403b4943e94cd954c77d01edc1963e4fc3b773a4f1042 SHA512 4767fea4c3a94fcf4ad6ca2a313ba1c10d9e6d0d593a63aa336f90f38599f1c43064f56c3e8fd18615ff08bd01dbc0cabe0bd01a798276075c160143f6102650

diff --git a/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild b/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild
new file mode 100644
index 00000000000..1f5014cfab2
--- /dev/null
+++ b/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils desktop xdg
+
+MY_PN="BffOrDie"
+DESCRIPTION="Time travelling alien couch co-op puzzle game for 1-4 players"
+HOMEPAGE="https://www.bffordie.com/"
+SRC_URI="${MY_PN}_Linux.zip"
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist fetch splitdebug"
+
+RDEPEND="
+	sys-libs/zlib
+	virtual/opengl
+"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+S="${WORKDIR}/${MY_PN}_Linux"
+
+DIR="/opt/${PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+pkg_nofetch() {
+	einfo "Please buy and download ${SRC_URI} from:"
+	einfo "  https://asa-studio.itch.io/${PN}"
+	einfo "and move it to your distfiles directory."
+}
+
+src_install() {
+	exeinto "${DIR}"
+	newexe ${MY_PN}.$(usex amd64 x86_64 x86) ${MY_PN}
+	make_wrapper ${PN} "${DIR}"/${MY_PN}
+
+	insinto "${DIR}"
+	doins -r ${MY_PN}_Data/
+	rm -r "${ED}/${DIR}"/${MY_PN}_Data/*/$(usex amd64 x86 x86_64) || die
+
+	# Some Unity games have a GUI launcher but this one doesn't use it.
+	rm "${ED}/${DIR}"/${MY_PN}_Data/Plugins/*/ScreenSelector.so || die
+
+	newicon -s 128 ${MY_PN}_Data/Resources/UnityPlayer.png ${PN}.png
+	make_desktop_entry ${PN} "BFF or Die"
+}

diff --git a/games-puzzle/bff-or-die/metadata.xml b/games-puzzle/bff-or-die/metadata.xml
new file mode 100644
index 00000000000..26079e608be
--- /dev/null
+++ b/games-puzzle/bff-or-die/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+</pkgmetadata>

[gentoo-commits] repo/gentoo:master commit in: games-puzzle/bff-or-die/

[Sam James]

commit:     4b2eeb1fc1d3e241183ed713a16f49c900a9c469
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  4 08:04:14 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Apr  4 08:13:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4b2eeb1f

games-puzzle/bff-or-die: eutils--, wrapper++

Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-puzzle/bff-or-die/bff-or-die-20200614.ebuild | 9 ++++-----
 1 file changed, 4 insertions(+), 5 deletions(-)

diff --git a/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild b/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild
index 1f5014cfab2..5d5a60d2416 100644
--- a/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild
+++ b/games-puzzle/bff-or-die/bff-or-die-20200614.ebuild
@@ -1,14 +1,16 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit eutils desktop xdg
+inherit desktop wrapper xdg
 
 MY_PN="BffOrDie"
 DESCRIPTION="Time travelling alien couch co-op puzzle game for 1-4 players"
 HOMEPAGE="https://www.bffordie.com/"
 SRC_URI="${MY_PN}_Linux.zip"
+S="${WORKDIR}/${MY_PN}_Linux"
+
 LICENSE="all-rights-reserved"
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
@@ -18,13 +20,10 @@ RDEPEND="
 	sys-libs/zlib
 	virtual/opengl
 "
-
 BDEPEND="
 	app-arch/unzip
 "
 
-S="${WORKDIR}/${MY_PN}_Linux"
-
 DIR="/opt/${PN}"
 QA_PREBUILT="${DIR#/}/*"