[gentoo-commits] repo/gentoo:master commit in: net-nds/tac_plus/

["Sam James" <sam@gentoo.org>]

commit:     591699ea45d46e23808c2286cc060c09e0a83c97
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 30 21:28:08 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Mar 30 21:45:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=591699ea

net-nds/tac_plus: install PAM configuration file

Thanks-to: Reuben Farrelly <reuben-gentoo-bugzilla <AT> reub.net>
Closes: https://bugs.gentoo.org/474860
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-nds/tac_plus/tac_plus-4.0.4.27a-r1.ebuild | 67 +++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/net-nds/tac_plus/tac_plus-4.0.4.27a-r1.ebuild b/net-nds/tac_plus/tac_plus-4.0.4.27a-r1.ebuild
new file mode 100644
index 00000000000..d1efa11dd8b
--- /dev/null
+++ b/net-nds/tac_plus/tac_plus-4.0.4.27a-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools pam
+
+MY_P="tacacs+-F${PV}"
+DESCRIPTION="An updated version of Cisco's TACACS+ server"
+HOMEPAGE="http://www.shrubbery.net/tac_plus/"
+SRC_URI="ftp://ftp.shrubbery.net/pub/tac_plus/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND RSA GPL-2" # GPL-2 only for init script
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug finger maxsess tcpd skey static-libs"
+
+DEPEND="
+	net-libs/libnsl
+	sys-libs/pam
+	skey? ( >=sys-auth/skey-1.1.5-r1 )
+	tcpd? ( sys-apps/tcp-wrappers )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-parallelmake.patch"
+	"${FILESDIR}/${P}-deansification.patch"
+)
+
+src_prepare() {
+	default
+
+	mv configure.in configure.ac || die "Unable to quiet autoconf deprecation warning"
+	AT_M4DIR="." eautoreconf
+
+}
+
+src_configure() {
+	econf \
+		$(use_with skey) \
+		$(use_with tcpd libwrap) \
+		$(use_enable debug) \
+		$(use_enable finger) \
+		$(use_enable maxsess) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use static-libs ; then
+		find "${ED}" -name '*.la' -delete || die "Unable to remove spurious libtool archive"
+	fi
+
+	dodoc CHANGES FAQ
+
+	newinitd "${FILESDIR}/tac_plus.init2" tac_plus
+	newconfd "${FILESDIR}/tac_plus.confd2" tac_plus
+
+	# bug #474860
+	pamd_mimic_system tac_plus auth account password session
+
+	insinto /etc/tac_plus
+	newins "${FILESDIR}/tac_plus.conf2" tac_plus.conf
+}