[gentoo-commits] repo/gentoo:master commit in: gnome-extra/nautilus-dropbox/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     3aa6cddf66334f95b04695e3cc9b9d0c8f731354
Author:     Jonas Licht <jonas.licht <AT> fem <DOT> tu-ilmenau <DOT> de>
AuthorDate: Mon Mar 22 18:08:47 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Mar 26 06:55:33 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3aa6cddf

gnome-extra/nautilus-dropbox: version bump to 2020.03.04

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Jonas Licht <jonas.licht <AT> fem.tu-ilmenau.de>
Closes: https://github.com/gentoo/gentoo/pull/20066
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 gnome-extra/nautilus-dropbox/Manifest              |  1 +
 .../nautilus-dropbox-2020.03.04.ebuild             | 67 ++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/gnome-extra/nautilus-dropbox/Manifest b/gnome-extra/nautilus-dropbox/Manifest
index af2b4ce4bbd..f814e00c41a 100644
--- a/gnome-extra/nautilus-dropbox/Manifest
+++ b/gnome-extra/nautilus-dropbox/Manifest
@@ -1 +1,2 @@
 DIST nautilus-dropbox-2019.02.14.tar.bz2 381416 BLAKE2B 0765196974d88caa477d962311efe05941cd2d25e35fa028720c8abed5120fea5abede74f39e00cb2ac9eb08d6d4bbdf1d1fe6db8d604c1803570209e654d55a SHA512 c5758d97fa40af1b27388c23289e5d1d98ef1c6db04ed7fb5cfee387723f72c34f3583fb6e0158a39f30d5ff649cb2de6d92fc4ad6e976e301dc239bda9d554b
+DIST nautilus-dropbox-2020.03.04.tar.bz2 387351 BLAKE2B ff25716ef10759e014cffec8a7e9b1a40931686d6de3c69e9060c77cbf3aee65ffeed91ba809ba8cffc372f284180c74a8cb5b0ca4b342aa137d9e574a2a1abf SHA512 8f26165a48d1767b3bccb34f95f19357e8fd209f383270ac2d40f773df139d640c3fb33db28cf1fa7e2d7063a7a37b15ed7f4f22f85019e05885c097cea39a48

diff --git a/gnome-extra/nautilus-dropbox/nautilus-dropbox-2020.03.04.ebuild b/gnome-extra/nautilus-dropbox/nautilus-dropbox-2020.03.04.ebuild
new file mode 100644
index 00000000000..6811ea493f9
--- /dev/null
+++ b/gnome-extra/nautilus-dropbox/nautilus-dropbox-2020.03.04.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools python-single-r1 xdg-utils
+
+DESCRIPTION="Dropbox Nautilus Extension"
+HOMEPAGE="https://github.com/dropbox/nautilus-dropbox"
+SRC_URI="https://linux.dropboxstatic.com/packages/${P}.tar.bz2"
+
+LICENSE="GPL-3 CC-BY-ND-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	gnome-base/nautilus
+	net-misc/dropbox
+	>=dev-libs/glib-2.14
+	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]' )"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	$(python_gen_cond_dep 'dev-python/docutils[${PYTHON_MULTI_USEDEP}]' )
+	virtual/pkgconfig"
+
+# use system rst2man
+PATCHES=( "${FILESDIR}/nautilus-dropbox-2019-system-rst2man.patch" )
+
+src_prepare() {
+	default
+
+	# use system dropbox
+	sed \
+		-e "s|~/[.]dropbox-dist|${EPREFIX}/opt/dropbox|" \
+		-e "s|\(DROPBOXD_PATH = \).*|\1\"${EPREFIX}/opt/dropbox/dropboxd\"|" \
+		-i dropbox.in || die
+	AT_NOELIBTOOLIZE=yes eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		--disable-static
+}
+
+src_install() {
+	default
+
+	# removes files which conflicts with system dropbox
+	rm -r "${D}/usr/share/applications" || die
+	rm -r "${D}/usr/bin" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update;
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update;
+}