[gentoo-commits] repo/gentoo:master commit in: dev-libs/libpeas/

["Matt Turner" <mattst88@gentoo.org>]

commit:     585bda2df1c47f70227997ab8061a01278df2fab
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 21 14:57:27 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Mar 21 15:01:33 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=585bda2d

dev-libs/libpeas: Version bump to 1.30.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libpeas/Manifest              |  1 +
 dev-libs/libpeas/libpeas-1.30.0.ebuild | 84 ++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/dev-libs/libpeas/Manifest b/dev-libs/libpeas/Manifest
index a39d3155163..7d991d09cf2 100644
--- a/dev-libs/libpeas/Manifest
+++ b/dev-libs/libpeas/Manifest
@@ -1,2 +1,3 @@
 DIST libpeas-1.26.0.tar.xz 191708 BLAKE2B 5845d5cb15724ba933572f48b9056a79cb2c167c7911ff1546c836fe56cd7e49d7461e5a413b79effa64e8e3fb2ed2eb370de665728e476e40ffb4d44c841543 SHA512 86157da14d17c16df2ef3f44ab48822ea1a8be8aec8f5419bc421bd475113f686cd16f9616ac53cbf3dc6f31f521384ac63eb8e9f1a46ea21b5cda8ba21e855f
 DIST libpeas-1.28.0.tar.xz 191896 BLAKE2B 64fd65228b4ae4be59724a9e4b26133ed025866d0b7bf15377d579c87de1ebdf1225e3a2aeb004ae9733544cc53782c399581b5fb5f1625ef55532600d37afe0 SHA512 43f8bc426238f519d7a3b26409af2f7578e921893c085d00fab74699a45649d8343e5646658003980e6639f51e74f3b25519c3bbc248d5161b11c999f7dd0374
+DIST libpeas-1.30.0.tar.xz 193108 BLAKE2B 071e24530934605a6364816165d8f47ac9c94887e80eda9175b163d9af64b2624d42df75c7697220e888f2f9150c6e121bd1dc2716de5bcf0d392722938de945 SHA512 10ebcc61c8aa42b5f6892a74d5e02a52dbc8fe4c35280d78f41adc915dd9c08e9756608f8cbdbaf3d63c44074f0b9e9e531dd077ba201b416acfdcfb94b4bc42

diff --git a/dev-libs/libpeas/libpeas-1.30.0.ebuild b/dev-libs/libpeas/libpeas-1.30.0.ebuild
new file mode 100644
index 00000000000..d011e421c63
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.30.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org lua-single meson python-single-r1 vala virtualx xdg
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="https://developer.gnome.org/libpeas/stable/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +gtk gtk-doc lua +python vala"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/gobject-introspection-1.39:=
+	gtk? ( >=x11-libs/gtk+-3.0.0:3[introspection] )
+	glade? ( >=dev-util/glade-3.9.1:3.10 )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			>=dev-lua/lgi-0.9.0[${LUA_USEDEP}]
+		')
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.2:3[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.11
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Gentoo-specific lua tweak hack
+	"${FILESDIR}"/1.26.0-lua.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature $(usex lua '!lua_single_target_luajit' 'lua') lua51)
+		$(meson_feature $(usex lua 'lua_single_target_luajit' 'lua') luajit)
+		-Dpython2=false
+		$(meson_use python python3)
+		# introspection was always enabled in autotools; would need readiness by consumers
+		# to USE flag it, but most need it for python plugins anyways
+		-Dintrospection=true
+		$(meson_use vala vapi)
+		$(meson_use gtk widgetry)
+		$(meson_use glade glade_catalog)
+		-Ddemos=false
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}