From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1262950-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2CA6C13835A
for <garchives@archives.gentoo.org>; Sun, 21 Mar 2021 00:33:41 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 427A3E086A;
Sun, 21 Mar 2021 00:33:40 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 06036E086A
for <gentoo-commits@lists.gentoo.org>; Sun, 21 Mar 2021 00:33:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 6DFDD33BED9
for <gentoo-commits@lists.gentoo.org>; Sun, 21 Mar 2021 00:33:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id E8CDE5B9
for <gentoo-commits@lists.gentoo.org>; Sun, 21 Mar 2021 00:33:36 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1616283295.8e9416326b9cd9f8c79cb7dc474369fb022b1b7f.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-control-center/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-base/gnome-control-center/Manifest gnome-base/gnome-control-center/gnome-control-center-3.38.5.ebuild
X-VCS-Directories: gnome-base/gnome-control-center/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: 8e9416326b9cd9f8c79cb7dc474369fb022b1b7f
X-VCS-Branch: master
Date: Sun, 21 Mar 2021 00:33:36 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: ce3c1b1c-edbc-4e8d-880d-377592f7b108
X-Archives-Hash: b960424ebd03e10c25f56e778f739dc3
commit: 8e9416326b9cd9f8c79cb7dc474369fb022b1b7f
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 20 23:34:55 2021 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Mar 20 23:34:55 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e941632
gnome-base/gnome-control-center: Version bump to 3.38.5
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
gnome-base/gnome-control-center/Manifest | 1 +
.../gnome-control-center-3.38.5.ebuild | 176 +++++++++++++++++++++
2 files changed, 177 insertions(+)
diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index 601758ee9e2..1a47062c47a 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -5,3 +5,4 @@ DIST gnome-control-center-3.36.5.tar.xz 6304804 BLAKE2B c4e95784ff1877e716f23ea4
DIST gnome-control-center-3.38.3-patchset.tar.xz 7308 BLAKE2B 72acdb825d48c7077d15f7273765db2ccbef89a839466a4482d9f6ae9eae3a2144556a048f2a6e146ea4e3435c13f0a72bf499c44d34bcbed505d6186d8bf008 SHA512 2498abd83e0100efa4c83886ce3e7f7d4468e41aab12c5338987832cb305c215abe75b4fff65217511bbe174b6b1b601af988c5588523e0346855aba7842092b
DIST gnome-control-center-3.38.3.tar.xz 6434672 BLAKE2B e95a9a1c487e1a3d6a0e64c61fd9502d1983827ff0a26ed03a0e48339917ae49855016ac3699c3940764185041659d865db51fd95e19bbb588c62277218c609d SHA512 25b8ff6e44be5e679666ae44e12deedf5dbef9317089381cd2075efc2321abca91ac1ad268242fb16a0b7f411ad98d9ab50073f745060d6525e0648585333e3e
DIST gnome-control-center-3.38.4.tar.xz 6434656 BLAKE2B 6201344c3ce4a1e85c8becde5df24d0aaa294ba0f135220fa1bd1ca079fb99ea30a4bb9f6403f17584bb1299b7d3edf1300fa94fca44a75bd947c84cc257be35 SHA512 9fa90b33af09fe5458c2db8782079d992f18bc36cdd6623239b48d6c8f242fa9b56275ee7c6920f313efcd2f8f1c65a43a8f3f1c100489a0bcade26d045eb3c7
+DIST gnome-control-center-3.38.5.tar.xz 6435648 BLAKE2B 6bcb91433540278850008b1a015caa157fede8533fc5fdf22b58a9f7511fe39a9c3dc195ed9aa1fcf729b6eaa2cf18cf67781300d43ed23ea63c3c6fc5cfb64f SHA512 d173dc863bb62010577a99c3f6705fd92c7e1b9fba124c7ab7fb32b22e01b23b75dea976b45e8d65e7329edca50fb892fe298e8ca2861c7e1185318b7be6cb67
diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.38.5.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.38.5.ebuild
new file mode 100644
index 00000000000..ac894c3d8ce
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.38.5.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-3.38.3-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind flickr +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test v4l wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+ flickr? ( gnome-online-accounts )
+ ^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+ >=gui-libs/libhandy-1:1=
+ gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.25.3:= )
+ >=media-sound/pulseaudio-2.0[glib]
+ >=sys-apps/accountsservice-0.6.39
+ >=x11-misc/colord-0.1.34:0=
+ >=x11-libs/gdk-pixbuf-2.23.0:2
+ >=dev-libs/glib-2.56.0:2
+ >=gnome-base/gnome-desktop-3.27.90:3=
+ >=gnome-base/gnome-settings-daemon-3.27.90[colord,input_devices_wacom?]
+ >=gnome-base/gsettings-desktop-schemas-3.37.0
+ dev-libs/libxml2:2
+ >=sys-auth/polkit-0.114
+ >=sys-power/upower-0.99.8:=
+ >=dev-libs/libgudev-232
+ x11-libs/libX11
+ >=x11-libs/libXi-1.2
+ media-libs/libepoxy
+ flickr? ( >=media-libs/grilo-0.3.0:0.3= )
+ >=x11-libs/gtk+-3.22.0:3[X,wayland=]
+ cups? (
+ >=net-print/cups-1.7[dbus]
+ >=net-fs/samba-4.0.0[client]
+ )
+ v4l? (
+ >=media-video/cheese-3.28.0 )
+ ibus? ( >=app-i18n/ibus-1.5.2 )
+ networkmanager? (
+ >=net-libs/libnma-1.8.0
+ >=net-misc/networkmanager-1.20.0:=[modemmanager]
+ >=net-misc/modemmanager-0.7.990 )
+ bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
+ input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+ kerberos? ( app-crypt/mit-krb5 )
+
+ x11-libs/cairo[glib]
+ >=x11-libs/colord-gtk-0.1.24
+ net-libs/libsoup:2.4
+ media-libs/fontconfig
+ gnome-base/libgtop:2=
+ >=sys-fs/udisks-2.1.8:2
+ app-crypt/libsecret
+ media-libs/gsound
+ >=dev-libs/libpwquality-1.2.2
+"
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+ systemd? ( >=sys-apps/systemd-31 )
+ elogind? ( app-admin/openrc-settingsd
+ sys-auth/elogind )
+ x11-themes/adwaita-icon-theme
+ >=gnome-extra/gnome-color-manager-3.1.2
+ cups? (
+ app-admin/system-config-printer
+ net-print/cups-pk-helper )
+ >=gnome-base/libgnomekbd-3
+ wayland? ( dev-libs/libinput )
+ !wayland? (
+ >=x11-drivers/xf86-input-libinput-0.19.0
+ input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+ flickr? ( media-plugins/grilo-plugins:0.3[flickr,gnome-online-accounts] )
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1
+ networkmanager? ( gnome-extra/nm-applet )" # networking panel can call into nm-connection-editor
+
+BDEPEND="
+ dev-libs/libxslt
+ app-text/docbook-xsl-stylesheets
+ app-text/docbook-xml-dtd:4.2
+ x11-base/xorg-proto
+ dev-libs/libxml2:2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ test? ( $(python_gen_any_dep '
+ dev-python/dbusmock[${PYTHON_USEDEP}]
+ ') )
+"
+
+PATCHES=(
+ # Patches from gnome-3-38 branch on top of 3.38.3
+ # Makes some panels and dependencies optional
+ # https://bugzilla.gnome.org/686840, 697478, 700145
+ # Fix some absolute paths to be appropriate for Gentoo
+ "${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+ use test && \
+ has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ xdg_src_prepare
+ # Mark python tests with shebang executable, so that meson will launch them directly, instead
+ # of via its own python-single-r1 version, which might not match what we get from python_check_deps
+ chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use bluetooth)
+ $(meson_use v4l cheese)
+ -Dcups=$(usex cups enabled disabled)
+ -Ddocumentation=true # manpage
+ -Dgoa=$(usex gnome-online-accounts enabled disabled)
+ -Dgrilo=$(usex flickr enabled disabled)
+ $(meson_use ibus)
+ -Dkerberos=$(usex kerberos enabled disabled)
+ -Dmalcontent=false # unpackaged
+ $(meson_use networkmanager network_manager)
+ -Dprivileged_group=wheel
+ -Dsnap=false
+ $(meson_use test tests)
+ $(meson_use debug tracing)
+ $(meson_use input_devices_wacom wacom)
+ #$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+ # bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}