[gentoo-commits] repo/gentoo:master commit in: sci-physics/fastjet/

["David Seifert" <soap@gentoo.org>]

commit:     836a2916760428bd6c9649f6f8559ecd42b35da7
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 20 12:12:30 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Mar 20 12:12:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=836a2916

sci-physics/fastjet: Port to EAPI 7

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-physics/fastjet/fastjet-3.0.6-r1.ebuild | 56 +++++++++++++++++------------
 1 file changed, 34 insertions(+), 22 deletions(-)

diff --git a/sci-physics/fastjet/fastjet-3.0.6-r1.ebuild b/sci-physics/fastjet/fastjet-3.0.6-r1.ebuild
index a7fec572825..b5cfe12ace3 100644
--- a/sci-physics/fastjet/fastjet-3.0.6-r1.ebuild
+++ b/sci-physics/fastjet/fastjet-3.0.6-r1.ebuild
@@ -1,12 +1,11 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
 FORTRAN_NEEDED=plugins
-AUTOTOOLS_AUTORECONF=1
 
-inherit autotools-utils fortran-2 flag-o-matic
+inherit autotools flag-o-matic fortran-2
 
 DESCRIPTION="Fast implementation of several recombination jet algorithms"
 HOMEPAGE="http://www.fastjet.fr/"
@@ -15,40 +14,53 @@ SRC_URI="http://www.fastjet.fr/repo/${P}.tar.gz"
 LICENSE="GPL-2 QPL"
 SLOT="0"
 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="cgal doc examples +plugins static-libs"
+IUSE="cgal doc examples +plugins"
 
-RDEPEND="cgal? ( sci-mathematics/cgal )"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen[dot] )
-	plugins? ( sci-physics/siscone:0= )"
+RDEPEND="
+	cgal? ( sci-mathematics/cgal:= )
+	plugins? ( sci-physics/siscone:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen[dot] )"
 
 PATCHES=( "${FILESDIR}"/${P}-system-siscone.patch )
 
+src_prepare() {
+	default
+	eautoreconf
+}
+
 src_configure() {
 	use cgal && \
-		has_version sci-mathematics/cgal[gmp] && append-ldflags -lgmp
-	local myeconfargs=(
-		$(use_enable cgal)
-		$(use_enable plugins allplugins)
+		has_version 'sci-mathematics/cgal[gmp]' && append-libs -lgmp
+
+	econf \
+		--disable-static \
+		$(use_enable cgal) \
+		$(use_enable plugins allplugins) \
 		$(use_enable plugins allcxxplugins)
-	)
-	autotools-utils_src_configure
 }
 
 src_compile() {
-	autotools-utils_src_compile
+	default
+
 	if use doc; then
 		doxygen Doxyfile || die
+		HTML_DOCS=( html/. )
 	fi
 }
 
 src_install() {
-	autotools-utils_src_install
-	use doc && dohtml -r html/*
+	default
+
 	if use examples; then
-		insinto /usr/share/doc/${PF}
-		find example \
-			-name Makefile -or Makefile.in -or Makefile.am -delete
-		doins -r example/*
+		emake -C example maintainer-clean
+		find example -iname 'makefile*' -delete || die
+
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
 	fi
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
 }