[gentoo-commits] repo/gentoo:master commit in: www-client/opera/

["Stephan Hartmann" <sultan@gentoo.org>]

commit:     9689835008dce2e55cec605cd2fcd12b9eb5ccb3
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 19 17:23:14 2021 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Fri Mar 19 17:26:21 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=96898350

www-client/opera: bump to 74.0.3911.232

Bug: https://bugs.gentoo.org/776331
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/opera/Manifest                   |   1 +
 www-client/opera/opera-74.0.3911.232.ebuild | 140 ++++++++++++++++++++++++++++
 2 files changed, 141 insertions(+)

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 9dda50dfe44..8f5d5adf030 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,2 +1,3 @@
 DIST opera-ffmpeg-codecs-88.0.4324.27.tar.xz 1362668 BLAKE2B 0815049dbf95996a04a072ad1b82664ef594e0ea99aaea5ea9d54448457bb5aa5c6d9cb95d6c84a14ca64a29e0a2e9c6f5315a1988eb577ad02cc7422fe0f886 SHA512 cd1857d302c413a52433839103a3a268a12ab255ad8d6e651e872f7f28b61e1426e3c2854fc9a6acf4430be9fa8fea939de288c800cc3c60696394f77d86146d
 DIST opera-stable_74.0.3911.203_amd64.deb 72976108 BLAKE2B 02342ef4d291bdd512a78ac0d2ae5da63d11b2cc999f0acc6ffe1ba9c9fe30a292b644d5239dc7481c4dff6c995985c1e1ee6f760240ef402f2740ce0928473e SHA512 ecffd6bc62a9d1e411358990add1e63e5d2a85614e47fc41b6f24eef9689291906516e779e5b9510e213ebf988841d21a88d57112ad510d97e6f8bf6b9ef4d3a
+DIST opera-stable_74.0.3911.232_amd64.deb 72911904 BLAKE2B 8e803ba1d0aed25f0b99e0b4fd4c8695381e54c8af607fa16ba08079e8ebdedd0c8d01381985553318bf9856ac399a95ec2ca91c67a0cc2d6b5e2e1c087837e5 SHA512 91a8e7219efcc076ca822a0e4fc313812dad8381ed40fed2260a88c3365fa3ecf3d36a301b507721131c436fe97a1da56a59380fef26b34dbc4254f3b4284c22

diff --git a/www-client/opera/opera-74.0.3911.232.ebuild b/www-client/opera/opera-74.0.3911.232.ebuild
new file mode 100644
index 00000000000..d9bfea79d1f
--- /dev/null
+++ b/www-client/opera/opera-74.0.3911.232.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib pax-utils unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="88.0.4324.27"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
+	proprietary-codecs? (
+		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid widevine"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	widevine? ( www-plugins/chrome-binary-plugins )
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	rm -r "usr/share/lintian" || die
+
+	# fix docs
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# symlink widevine
+	rm "${OPERA_HOME}/resources/widevine_config.json" || die
+	if use widevine; then
+		echo "[\"${EPREFIX}/usr/$(get_libdir)/chromium-browser/WidevineCdm\"]" > \
+			"${OPERA_HOME}/resources/widevine_config.json" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}