[gentoo-commits] repo/gentoo:master commit in: dev-java/xalan-serializer/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     a04bda69ce003bf0557ec7803fc847195ebec9ff
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 16 11:18:33 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Tue Mar 16 11:18:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a04bda69

dev-java/xalan-serializer: eapi7 + jdk 11 compilation fix

based on https://github.com/gentoo/gentoo/pull/19946

Closes: https://github.com/gentoo/gentoo/pull/19946
Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 .../xalan-serializer-2.7.2-r1.ebuild               | 41 ++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/dev-java/xalan-serializer/xalan-serializer-2.7.2-r1.ebuild b/dev-java/xalan-serializer/xalan-serializer-2.7.2-r1.ebuild
new file mode 100644
index 00000000000..1f6ae506e46
--- /dev/null
+++ b/dev-java/xalan-serializer/xalan-serializer-2.7.2-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_PV="$(ver_rs 1- '_')"
+MY_P="xalan-j_${MY_PV}"
+
+DESCRIPTION="DOM Level 3 serializer from Apache Xalan, shared by Xalan and Xerces"
+HOMEPAGE="https://xalan.apache.org/"
+SRC_URI="mirror://apache/xalan/xalan-j/source/${MY_P}-src.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND=">=virtual/jre-1.8:*"
+DEPEND=">=virtual/jdk-1.8:*"
+
+JAVA_SRC_DIR="src"
+JAVA_RESOURCE_DIRS="resources"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	# kill all non-serializer sources to ease javadocs and dosrc
+	find src/org/ -type f ! -path "src/org/apache/xml/serializer/*" -delete || die
+
+	# remove bundled jars
+	find -name "*.jar" -delete || die
+	rm src/*.tar.gz || die
+
+	# move resources elsewhere
+	mkdir -p resources/org/apache/xml/serializer || die
+	mv src/org/apache/xml/serializer/*.properties resources/org/apache/xml/serializer/ || die
+}