[gentoo-commits] repo/gentoo:master commit in: sci-libs/gamer/

[gentoo-commits] repo/gentoo:master commit in: sci-libs/gamer/

[David Seifert]

commit:     eb7afe669b6ab971485407b2ba5bde3db7a15ecc
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 13 18:50:34 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Mar 13 18:50:34 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb7afe66

sci-libs/gamer: Port to EAPI 7

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/gamer/gamer-1.5-r2.ebuild | 59 +++++++++++++++++++-------------------
 1 file changed, 30 insertions(+), 29 deletions(-)

diff --git a/sci-libs/gamer/gamer-1.5-r2.ebuild b/sci-libs/gamer/gamer-1.5-r2.ebuild
index 23cbb803366..e8fc10d9482 100644
--- a/sci-libs/gamer/gamer-1.5-r2.ebuild
+++ b/sci-libs/gamer/gamer-1.5-r2.ebuild
@@ -1,51 +1,52 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-AUTOTOOLS_AUTORECONF=yes
-
-inherit autotools-utils multilib
+inherit autotools
 
 DESCRIPTION="Geometry-preserving Adaptive MeshER"
 HOMEPAGE="http://fetk.org/codes/gamer/index.html"
 SRC_URI="http://www.fetk.org/codes/download/${P}.tar.gz"
+S="${WORKDIR}/${PN}"
 
+LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
-LICENSE="GPL-2"
-IUSE="doc static-libs"
+IUSE="doc"
 
 RDEPEND=">=dev-libs/maloc-1.4"
-DEPEND="
-	${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	doc? (
 		media-gfx/graphviz
 		app-doc/doxygen
-		)"
-
-S="${WORKDIR}"/${PN}
+	)"
 
 PATCHES=(
 	"${FILESDIR}"/1.4-multilib.patch
 	"${FILESDIR}"/1.4-doc.patch
-	)
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
 
 src_configure() {
-	local fetk_include
-	local fetk_lib
-	local myeconfargs
-
-	use doc || myeconfargs+=( ${myconf} --with-doxygen= --with-dot= )
-
-	fetk_include="${EPREFIX}"/usr/include
-	fetk_lib="${EPREFIX}"/usr/$(get_libdir)
-	export FETK_INCLUDE="${fetk_include}"
-	export FETK_LIBRARY="${fetk_lib}"
-
-	myeconfargs+=(
-		--docdir="${EPREFIX}"/usr/share/doc/${PF}
-		--disable-triplet
-		)
-	autotools-utils_src_configure
+	export FETK_INCLUDE="${ESYSROOT}"/usr/include
+	export FETK_LIBRARY="${ESYSROOT}"/usr/$(get_libdir)
+
+	econf \
+		--disable-static \
+		--disable-triplet \
+		--with-doxygen=$(usex doc "${BROOT}"/usr/bin/doxygen '') \
+		--with-dot=$(usex doc "${BROOT}"/usr/bin/dot '')
+}
+
+src_install() {
+	default
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
 }