From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1259883-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 3030613835D
	for <garchives@archives.gentoo.org>; Thu, 11 Mar 2021 18:54:41 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 5A231E08F7;
	Thu, 11 Mar 2021 18:54:40 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 2D8E5E08F7
	for <gentoo-commits@lists.gentoo.org>; Thu, 11 Mar 2021 18:54:40 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id DEB19340C74
	for <gentoo-commits@lists.gentoo.org>; Thu, 11 Mar 2021 18:54:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 22D30597
	for <gentoo-commits@lists.gentoo.org>; Thu, 11 Mar 2021 18:54:36 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1615488845.32c8654b785f8ad7d7c89f2f591376001c26ccbe.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/lldb/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-util/lldb/Manifest dev-util/lldb/lldb-12.0.0_rc3.ebuild
X-VCS-Directories: dev-util/lldb/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 32c8654b785f8ad7d7c89f2f591376001c26ccbe
X-VCS-Branch: master
Date: Thu, 11 Mar 2021 18:54:36 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 0f45c01d-22cd-4253-8408-29a3a9354562
X-Archives-Hash: daaa9eef320f562138efc9b078ab94fd

commit:     32c8654b785f8ad7d7c89f2f591376001c26ccbe
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 11 15:36:41 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar 11 18:54:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=32c8654b

dev-util/lldb: Bump to 12.0.0-rc3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/lldb/Manifest               |   1 +
 dev-util/lldb/lldb-12.0.0_rc3.ebuild | 102 +++++++++++++++++++++++++++++++++++
 2 files changed, 103 insertions(+)

diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index d16aefb2a74..9f09664b63b 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -3,3 +3,4 @@ DIST llvmorg-11.0.0.tar.gz 122743665 BLAKE2B 3f95570240789fd68ddb747df817f5c6cdc
 DIST llvmorg-11.0.1.tar.gz 122790338 BLAKE2B 0130996b4a8c4d9f757136fd7fb318068c9bfdc565060dec0d4336480c4ab66c4ae3185a7fdb05f13cf9ee8fd4123b09df938881b75d6e5d3689595114b7e32a SHA512 f5e6ef0b3111aae08a89cd01adb2ff4abfa9ef779c68b9190421d0447efd25c2cc00e5aae9f4764805f5fa31434866043d1510ae7389817e28ae53a5442e2fdf
 DIST llvmorg-11.1.0.tar.gz 122776532 BLAKE2B ca842ff4afff8f44c82b5e7383962a9c45ca1c93b64fa4c6ebcd70a1d3849dbad2b8e4e24fba02d144c6266d7fab3607ebc6999b28c229cb35256cf40f26a985 SHA512 9a8ce022a935eed42fa71a224f2a207122aadcbef58ee855fdb4825f879e7d028e4dcff22c19b9d336db1c8bf63fb84372d44981acf84615f757e54306c92b81
 DIST llvmorg-12.0.0-rc2.tar.gz 134242619 BLAKE2B bb741a311db608fc2ba7eeaab71c5c9f2a430f7fee3f0c5c4334e5c14caa19738d18c87b568de963d57d9b53e808ac412cf8554eca7fcae9ecca65aa4442e197 SHA512 d8f9b3dfeb0fe9b91eb7f49da393784333044db2653373fbb168afd3c8d50f3e3ec7a7b8f44df522d0facafbfe4cfc4d9e2906d19f1e6feb0bdc569b6c10a17d
+DIST llvmorg-12.0.0-rc3.tar.gz 134244008 BLAKE2B ed09aa361b264387711ba1ee2e4b01c0c78ad97391df95e2542d4edc31f657cc33c8a2a45de63eb421908d5dadd9392a736610fbb04b3ecbd336d6514a649da8 SHA512 1fae53c6f255160cf4be53848b8b92c8b162ddcfbddf1bf0017faf249859040c15c862c4b52bc3ba894149139afb814e0674da88793ddebfc0756ba3aa7626ce

diff --git a/dev-util/lldb/lldb-12.0.0_rc3.ebuild b/dev-util/lldb/lldb-12.0.0_rc3.ebuild
new file mode 100644
index 00000000000..283e64ba210
--- /dev/null
+++ b/dev-util/lldb/lldb-12.0.0_rc3.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit cmake llvm llvm.org python-single-r1 toolchain-funcs
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="+libedit lzma ncurses +python test"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+RESTRICT="test"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	lzma? ( app-arch/xz-utils:= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/six[${PYTHON_USEDEP}]
+		')
+		${PYTHON_DEPS}
+	)
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/cmake-3.16
+	python? ( >=dev-lang/swig-3.0.11 )
+	test? (
+		$(python_gen_cond_dep "
+			~dev-python/lit-${PV}[\${PYTHON_USEDEP}]
+			dev-python/psutil[\${PYTHON_USEDEP}]
+		")
+		sys-devel/lld
+	)
+	${PYTHON_DEPS}"
+
+LLVM_COMPONENTS=( lldb )
+LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
+llvm.org_set_globals
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLDB_ENABLE_CURSES=$(usex ncurses)
+		-DLLDB_ENABLE_LIBEDIT=$(usex libedit)
+		-DLLDB_ENABLE_PYTHON=$(usex python)
+		-DLLDB_ENABLE_LZMA=$(usex lzma)
+		-DLLDB_USE_SYSTEM_SIX=1
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		-DCLANG_LINK_CLANG_DYLIB=ON
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+
+		-DLLDB_EXTERNAL_CLANG_RESOURCE_DIR="${BROOT}/usr/lib/clang/${PV%_*}"
+
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=$(usex test)
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lldb-lit
+	# failures + hangs
+	#use python && cmake_build check-lldb
+}
+
+src_install() {
+	cmake_src_install
+	find "${D}" -name '*.a' -delete || die
+
+	use python && python_optimize
+}