[gentoo-commits] repo/gentoo:master commit in: sci-astronomy/kstars/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     9a080655d071ea2447c0a9a2c8d80dc11e799576
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  5 15:11:29 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Mar  5 16:22:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a080655

sci-astronomy/kstars: 3.5.2 version bump

Package-Manager: Portage-3.0.16, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-astronomy/kstars/Manifest            |  1 +
 sci-astronomy/kstars/kstars-3.5.2.ebuild | 98 ++++++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/sci-astronomy/kstars/Manifest b/sci-astronomy/kstars/Manifest
index eb147712fec..84bfb241bee 100644
--- a/sci-astronomy/kstars/Manifest
+++ b/sci-astronomy/kstars/Manifest
@@ -1 +1,2 @@
 DIST kstars-3.5.1.tar.xz 78872552 BLAKE2B 8962d60a7e6224a7d6724a9883136599ca7acf874131b46ad30ca5fba6d222242d60f3eff3bee8df3e7db8807e6d6a3d363d2f63dd1540d7b80d9f76be3ee31f SHA512 a0684272967a314ca9ce5d835337d6c6f52f2b5cfb877f50b41a5fa8df51497fbb10445e14e0d04804f3ad3dfdba4379710dd82547b617f4ee9d78cec8feb0dc
+DIST kstars-3.5.2.tar.xz 78893892 BLAKE2B 3fc5c0544b3145af770f59b7c4ddbca3578c03a44e87b3114c1ca414242da9df44eb8cfe1440f1c55491a8e73ff329e8e4482c6becb610683fd2fb210a16dd2e SHA512 0ddd2987b4c34ff4d8a6287c61601eb33311d2403b3f1b0e503aa4bb6adb2b61f9c5d3aedfc7146b3503d2da6a0a9c6dd73d237135a06a7c824c84699bac0f3f

diff --git a/sci-astronomy/kstars/kstars-3.5.2.ebuild b/sci-astronomy/kstars/kstars-3.5.2.ebuild
new file mode 100644
index 00000000000..2d2668552f2
--- /dev/null
+++ b/sci-astronomy/kstars/kstars-3.5.2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.74.0
+QTMIN=5.15.1
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Desktop Planetarium"
+HOMEPAGE="https://apps.kde.org/en/kstars https://edu.kde.org/kstars/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="5"
+IUSE="fits indi +password raw wcs"
+
+REQUIRED_USE="indi? ( fits ) ${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdatavis3d-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebsockets-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	fits? ( sci-libs/cfitsio:= )
+	indi? (
+		sci-libs/gsl:=
+		>=sci-libs/indilib-1.7.5
+		sci-libs/libnova:=
+		sci-libs/stellarsolver
+	)
+	password? ( dev-libs/qtkeychain:= )
+	raw? ( media-libs/libraw:= )
+	wcs? ( sci-astronomy/wcslib:= )
+"
+# TODO: Add back when re-enabled by upstream
+# 	opengl? (
+# 		>=dev-qt/qtopengl-${QTMIN}:5
+# 		virtual/opengl
+# 	)
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/eigen:3
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpositioning-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFETCH_TRANSLATIONS=OFF
+		-DBUILD_DOC=$(usex handbook)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package indi INDI)
+		$(cmake_use_find_package indi Nova)
+		$(cmake_use_find_package password Qt5Keychain)
+		$(cmake_use_find_package raw LibRaw)
+		$(cmake_use_find_package wcs WCSLIB)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "Display 'current' pictures of planets" x11-misc/xplanet
+	fi
+	ecm_pkg_postinst
+}