[gentoo-commits] repo/gentoo:master commit in: sci-libs/indilib/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     0dd941199ec7968c91f37f850da8bdd27d8efa66
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  5 15:10:27 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Mar  5 16:22:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0dd94119

sci-libs/indilib: 1.8.9 version bump

Package-Manager: Portage-3.0.16, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-libs/indilib/Manifest             |  1 +
 sci-libs/indilib/indilib-1.8.9.ebuild | 56 +++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index c510e5c9d3d..46dff4fdc78 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1 +1,2 @@
 DIST indilib-1.8.8.tar.gz 2234987 BLAKE2B 542c77e1826002e6268be82048014cdd7db2e58d6860bf21e058775acccbca49091218c24d5910f91705aebcf592e21f9008d780f39bb0458115b073319e3949 SHA512 0598b117fa582daaaf7c71524fd40866a37fcdc47b523b2ee1ed3301701c7351b027a3aab794e2e1405aec7293ecc6705d5f7852bb472cd21f40d7e3d7733d1d
+DIST indilib-1.8.9.tar.gz 2253721 BLAKE2B 477880606867ef58e334efeb8d891996187833cdb2f6344018a47c36ad51cfe983e645d92be3e868246bc8dd730d51927834ad73efb2db5edb2ce238ae6d32f6 SHA512 7d561e3619a1ff9e4ec96c54d339f5a85b6d2f4adde57630044fa7f2a8d70c74488ab22eb6221de62c0738bb9c9d187b86b67c4e47f4f98a237d4f69731fe906

diff --git a/sci-libs/indilib/indilib-1.8.9.ebuild b/sci-libs/indilib/indilib-1.8.9.ebuild
new file mode 100644
index 00000000000..e6ee5b9fd22
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.8.9.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ogg test websocket"
+
+RDEPEND="
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/libusb:0
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${P/lib/}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+}