[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Stephan Hartmann" <sultan@gentoo.org>]

commit:     5500a24d4e870d63e6c3776926ae9df04cb411a0
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  4 19:04:44 2021 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Thu Mar  4 19:04:44 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5500a24d

www-client/opera-beta: bump to 75.0.3969.35

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 +
 .../opera-beta/opera-beta-75.0.3969.35.ebuild      | 139 +++++++++++++++++++++
 2 files changed, 140 insertions(+)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index dd5ab516720..4c0fd558296 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,2 +1,3 @@
 DIST opera-beta_75.0.3969.14_amd64.deb 74649684 BLAKE2B 626b264c738c9cc44edad13ac4ef395cbdec89c6278fd9e7c9997c54bf0658d806cb068868dfa96fa65c52f04ba31f9a8ac0a241c5f55cf56f9248dbb9a25de4 SHA512 2322e0b78df9824aacd7a445b9633fefa58df49f94c59447f1b2279c512cbcbbfb3c005c7c8ca7bdc6eaa3a1ea968839887119ba66d80af6da4a6d9580571e6b
+DIST opera-beta_75.0.3969.35_amd64.deb 74668108 BLAKE2B b44cc245a0ed74ced5bf93de039abb6f5c3d9267308280bde6566c429bda4b5144b8efda05db2fdc5b62f46ad7e4a0cfb710613a935a74cb11ad152563b35a42 SHA512 8cd07ebb87bb58841c56ba8635e491aba3e97d8c2c271eff2af59fa8c0cc9a587ec2b9aabb962d6768e2e03f117c308b7caff2062b349cebc4edd7b788a521b5
 DIST opera-ffmpeg-codecs-89.0.4381.8.tar.xz 1427048 BLAKE2B 6f92f8582663b46875f4a3d9b0b80b14eb8b361b23699bd5e10319c9b16b26a436cd710cec684a818189eae4892fc41daf2b3387282926e964d4d395a1c7778e SHA512 7947eeaa361e78d1a69d244727ad601719fd4e6d6c284b1655e9fd9c74cf718f42ba3e0d0277f96a7b9cab984d743ea190404e2f74b5e1a6b9bd244e45b71e77

diff --git a/www-client/opera-beta/opera-beta-75.0.3969.35.ebuild b/www-client/opera-beta/opera-beta-75.0.3969.35.ebuild
new file mode 100644
index 00000000000..e4d998d6b85
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-75.0.3969.35.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib pax-utils unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	KEYWORDS="-* amd64"
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	KEYWORDS="-* ~amd64"
+	MY_PN=${PN}
+fi
+
+FFMPEG_VERSION="89.0.4381.8"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
+	proprietary-codecs? (
+		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid widevine"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa[gbm]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	widevine? ( www-plugins/chrome-binary-plugins )
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	rm -r "usr/share/lintian" || die
+
+	# fix docs
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# symlink widevine
+	rm "${OPERA_HOME}/resources/widevine_config.json" || die
+	if use widevine; then
+		echo "[\"${EPREFIX}/usr/$(get_libdir)/chromium-browser/WidevineCdm\"]" > \
+			"${OPERA_HOME}/resources/widevine_config.json" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}