[gentoo-commits] repo/gentoo:master commit in: dev-python/moto/

["Michał Górny" <mgorny@gentoo.org>]

commit:     de1c8b410931a8910af74a4877cf7b8d50ea6bf7
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  4 08:07:49 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar  4 08:57:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de1c8b41

dev-python/moto: Bump to 2.0.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/moto/Manifest          |  1 +
 dev-python/moto/moto-2.0.1.ebuild | 75 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 899b2bf63f6..95699ecf144 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,3 +1,4 @@
 DIST moto-1.3.14.tar.gz 1829165 BLAKE2B 2ec30c4cc571492a9d2c08f66a39ad04cfc0baa7864db8a5be4ea9af24ecb59bad3e85c44fa8a7babc16bf66188cb6bef89484f1f302a11e6eec1f8dbf516492 SHA512 1fe7e9d49dadada82f24d6bef1c21419c414e027c21ed1099bd1eab7c269ac5638ed44a29d1557b37562a44b22a7c7251fc1ca8ba88cde6b82d39dbc620aa6a6
 DIST moto-1.3.16.tar.gz 1761006 BLAKE2B adb48ac770e0753403fd41309ebc2085e5d9cdfad5dc791d9cc1216af10e55038c37526a8549a034a3327d821c56b0f6cdd775a17336285bfc637c09191dd78d SHA512 80a1335fea8d6dd42b4062365da4719d26cd6c18e5c186c950bbb844dce44e91ffe5e5173742f3b60d6ba2cab93d45359b43c2cb0ccf74d16009986457c243a4
 DIST moto-2.0.0.tar.gz 5054551 BLAKE2B be9b18909f90b22fe57d47e2eea50144b4ac8046dde0123249079f53c8f3c2ea70513b29cde1030ad923be7d50c6021351c8aa9c65bc0b95510a4f4de9d4d111 SHA512 285eff39004b291d112c455f44e30fe441d74c08aff614f5c97e7c52a68edb200d7077722f1e7bca38a63694aabf2ff56994cd1229e449b2f1afdf3945735fc7
+DIST moto-2.0.1.tar.gz 1530088 BLAKE2B eb35bcbc8b22044ae86eaa6eb1f71eb24174a8686ef06d475c870ef629d0a525719c4f153cb0a55fa27f3c33568a5796a07ce903800468557dfe275de3da3623 SHA512 d650140c76a2090332fd9f4c8be84379d4e578a63125d473b821d59bff9f93ee8e696268e4784df13f2ee3b8b6967fd10cbd94750f37e63967ed679b4a301682

diff --git a/dev-python/moto/moto-2.0.1.ebuild b/dev-python/moto/moto-2.0.1.ebuild
new file mode 100644
index 00000000000..8984175648d
--- /dev/null
+++ b/dev-python/moto/moto-2.0.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-python-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	dev-python/dicttoxml[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unping indirect dep on ecdsa that's supposed to workaround pip
+	# bugs
+	sed -i -e '/ecdsa/s:<0.15::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		# network
+		tests/test_stepfunctions/test_stepfunctions.py::test_state_machine_creation_fails_with_invalid_names
+	)
+
+	pytest -vv -m 'not network' ${deselect[@]/#/--deselect } ||
+		die "Tests fail with ${EPYTHON}"
+}