[gentoo-commits] repo/gentoo:master commit in: net-misc/gsutil/

["Mike Frysinger" <vapier@gentoo.org>]

commit:     777dc0f6d517be7abea8c4567ab9bcd0cf86ced1
Author:     Mike Frysinger <vapier <AT> chromium <DOT> org>
AuthorDate: Tue Mar  2 21:31:44 2021 +0000
Commit:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
CommitDate: Tue Mar  2 21:32:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=777dc0f6

net-misc/gsutil: version bump to 4.59

Signed-off-by: Mike Frysinger <vapier <AT> gentoo.org>

 net-misc/gsutil/Manifest           |  1 +
 net-misc/gsutil/gsutil-4.59.ebuild | 97 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/net-misc/gsutil/Manifest b/net-misc/gsutil/Manifest
index 9f70bca12bf..35a713a7999 100644
--- a/net-misc/gsutil/Manifest
+++ b/net-misc/gsutil/Manifest
@@ -1 +1,2 @@
 DIST gsutil_4.50.tar.gz 3618295 BLAKE2B bbd8ec13428a9822b1ebe3eea984f3e50abc010a0de4e57e7dc365642ab501f7994a235d778eaa73c8217ae1e69d1569e80ac8a59d94a84a6abb8272ad466a35 SHA512 aa7d68f369ac24c75cbd321d9a1a943fc361e9bf768797327852d0da39d364fa95ac3891367e90a39061b30b331405e2ea8358e0c91e3bdc5cb151d367e0857e
+DIST gsutil_4.59.tar.gz 4024669 BLAKE2B 4317cd3787adae2d7d066d7c8d5c62cfe77749d4efc8b5451e87ac6294de0e6f13c085795de30a891f2d7b58cd7e0724234cf14b4308542c8d050856a868c5cf SHA512 c86b957a2630f3a80869e3105c0baa7bf1297b84698e756fed28b28adf36345cf1dd28d4216ec395de6bfee5b118dd70040ff964a2938f22d8af15a5c3485c48

diff --git a/net-misc/gsutil/gsutil-4.59.ebuild b/net-misc/gsutil/gsutil-4.59.ebuild
new file mode 100644
index 00000000000..48e12ee2207
--- /dev/null
+++ b/net-misc/gsutil/gsutil-4.59.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="command line tool for interacting with cloud storage services"
+HOMEPAGE="https://github.com/GoogleCloudPlatform/gsutil"
+SRC_URI="http://commondatastorage.googleapis.com/pub/${PN}_${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/boto-2.49.0[${PYTHON_USEDEP}]
+	>=dev-python/crcmod-1.7[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+	>=dev-python/gcs-oauth2-boto-plugin-2.7[${PYTHON_USEDEP}]
+	>=dev-python/google-apitools-0.5.30[${PYTHON_USEDEP}]
+	>=dev-python/google-reauth-python-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.18[${PYTHON_USEDEP}]
+	>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-1.4[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+	>=dev-python/retry-decorator-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/gsutil-4.41-tests.patch"
+	"${FILESDIR}/gsutil-4.50-boto-tests.patch"
+	"${FILESDIR}/gsutil-4.50-tests.patch"
+)
+
+S="${WORKDIR}/${PN}"
+
+DOCS=( README.md CHANGES.md )
+
+# needs to talk to Google to run tests
+RESTRICT+=" test"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# NB: We don't delete all of boto/ because the tests are imported by the
+	# production code.  The same reason we can't delete gslib/tests/.  We can
+	# delete the main boto library and use the system version though.
+	rm -r gslib/vendored/boto/boto || die
+
+	# failes to compile with py3
+	rm gslib/vendored/boto/tests/mturk/cleanup_tests.py || die
+
+	sed -i \
+		-e 's/mock==/mock>=/' \
+		setup.py || die
+	# Sanity check we didn't miss any updates.
+	grep '==' setup.py && die "Need to update version requirements"
+
+	# For debugging purposes, temporarily uncomment this in order to
+	# show hidden tracebacks.
+	#sed -e 's/^  except OSError as e:$/&\n    raise/' \
+	#	-e 's/def _HandleUnknownFailure(e):/&\n  raise/' \
+	#	-i gslib/__main__.py || die
+
+	# create_bucket raised ResponseNotReady
+	sed -i \
+		-e 's/test_cp_unwritable_tracker_file/_&/' \
+		-e 's/test_cp_unwritable_tracker_file_download/_&/' \
+		gslib/tests/test_cp.py || die
+
+	sed -i -E -e 's/(executable_prefix =).*/\1 [sys.executable]/' \
+		gslib/commands/test.py || die
+
+	# IOError: close() called during concurrent operation on the same file object.
+	sed -i -e 's/sys.stderr.close()/#&/' \
+		gslib/tests/testcase/unit_testcase.py || die
+}
+
+python_compile() {
+	2to3 --write --nobackups --no-diffs -j "$(makeopts_jobs "${MAKEOPTS}" INF)" \
+		gslib/vendored/boto/tests || die "2to3 on boto tests failed"
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	BOTO_CONFIG="${FILESDIR}/dummy.boto" \
+		"${EPYTHON}" gslib/__main__.py test -u || die "tests failed with ${EPYTHON}"
+}