[gentoo-commits] repo/gentoo:master commit in: sci-mathematics/bertini/

[gentoo-commits] repo/gentoo:master commit in: sci-mathematics/bertini/

[Sam James]

commit:     5820c86bb7c0db9e037eceebe14a52eef01adc37
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 27 04:32:06 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Feb 27 04:32:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5820c86b

sci-mathematics/bertini: EAPI 7, gcc 10, CFLAGS

Closes: https://bugs.gentoo.org/723328
Closes: https://bugs.gentoo.org/731944
Package-Manager: Portage-3.0.15, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sci-mathematics/bertini/bertini-1.4.ebuild | 46 ++++++++++++++++--------------
 1 file changed, 25 insertions(+), 21 deletions(-)

diff --git a/sci-mathematics/bertini/bertini-1.4.ebuild b/sci-mathematics/bertini/bertini-1.4.ebuild
index 8eb1c6cae69..2ad14ca941e 100644
--- a/sci-mathematics/bertini/bertini-1.4.ebuild
+++ b/sci-mathematics/bertini/bertini-1.4.ebuild
@@ -1,22 +1,22 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-inherit toolchain-funcs
+inherit toolchain-funcs flag-o-matic
 
 MYP="BertiniSource_v${PV}"
-
 DESCRIPTION="Software for Numerical Algebraic Geometry"
 HOMEPAGE="http://bertini.nd.edu"
-
 SRC_URI="http://www3.nd.edu/~sommese/bertini/${MYP}.tar.gz"
+S="${WORKDIR}/${MYP}/src"
 
 LICENSE="bertini"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="doc examples +optimization"
-DEPEND="
+
+BDEPEND="
 	sys-devel/bison
 	sys-devel/flex
 "
@@ -24,34 +24,38 @@ RDEPEND="
 	dev-libs/gmp
 	dev-libs/mpfr
 "
-
-S="${WORKDIR}/${MYP}/src"
+DEPEND="${RDEPEND}"
 
 src_prepare() {
+	default
+
+	# bug #723328
+	append-cflags -fcommon
+
+	# Ensure this is before the CFLAGS sed
+	# or breakage occurs if 'gcc' is in your CFLAGS
+	sed -i -e "s/gcc/$(tc-getCC)/" Makefile || die
+
 	if ! use optimization; then
-		sed -i -e "s/\$(OPT)/ ${CXXFLAGS} ${LDFLAGS}/" Makefile
+		sed -i -e "s/\$(OPT)/ ${CFLAGS} ${CXXFLAGS} ${LDFLAGS}/" Makefile || die
 	else
-		sed -i -e "s/\$(OPT)/ \$(OPT) ${LDFLAGS}/" Makefile
+		# If people want the optimisation offered by upstream,
+		# let's ensure they don't accidentally override it.
+		filter-flags -O?
+		sed -i -e "s/\$(OPT)/ \$(OPT) ${CFLAGS} ${LDFLAGS}/" Makefile || die
 	fi
-	sed -i -e "s/gcc/$(tc-getCC)/" Makefile
-}
-
-src_configure() {
-	:
-}
-
-src_compile() {
-	emake
 }
 
 src_install() {
 	dobin bertini
+
 	if use doc; then
 		dodoc "${WORKDIR}/${MYP}/BertiniUsersManual.pdf"
 	fi
+
 	if use examples; then
-		insinto "/usr/share/${PN}"
-		doins -r "${WORKDIR}/${MYP}/examples"
+		docinto examples
+		dodoc -r "${WORKDIR}/${MYP}/examples"
 		elog "Examples have been installed into /usr/share/${MYP}"
 	fi
 }

[gentoo-commits] repo/gentoo:master commit in: sci-mathematics/bertini/

[Maciej Barć]

commit:     bfd4e2ef685efc640a868f92dd0504d4161053cf
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  6 17:22:47 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Feb  6 17:23:18 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bfd4e2ef

sci-mathematics/bertini: bump to 1.6

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 sci-mathematics/bertini/Manifest           |  2 +
 sci-mathematics/bertini/bertini-1.6.ebuild | 65 ++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/sci-mathematics/bertini/Manifest b/sci-mathematics/bertini/Manifest
index 28ac95662aee..a1ce4e64694e 100644
--- a/sci-mathematics/bertini/Manifest
+++ b/sci-mathematics/bertini/Manifest
@@ -1 +1,3 @@
 DIST BertiniSource_v1.4.tar.gz 1827401 BLAKE2B 4869ef0b73a3688df504bff84dc36682700c4916dcfdca68ae3a1bf87ceda2f664c35e2b5fe4b5d0859bbab110a2fa1e474361847db897859c3d5d17c48f122f SHA512 bb53f8ed24a0f21e95b4e373be36039b69ea0ddb11ad8240bcf52ce64436a56c1f2057a5d733d017fdf68cfb3598a473e1f12b4659308890e2e2575b7d8143f6
+DIST BertiniSource_v1.6.tar.gz 4957384 BLAKE2B 395ca96c52b167eaefe672d31c79c5791d92b1375059c0e6244042f2e987d011d0c9b5d6590555654e0b23d15aec2dcdcb2c1fa23fec73fb5c0e307c960c334b SHA512 04e0964e714ede697d49aeecd4008102d653472664d22fc2f491e93d8a5cc18a9db2980d57a23a8ea88f1fab9b98aeb2d36fc112c0a0aa3510e152a8edcb1f95
+DIST BertiniUsersManual.pdf 1188567 BLAKE2B d940e95a86ec2b81d5afff3ade9fe28f5c3034e9250a844d3b8ad4de5ded1b4b98a68d2da1f61e17fd7f25ed481522805505850fc011f2a5642ca7cee4e86c8f SHA512 f206645cf20eb4da9e00b62440e612e0037fe02882167cdb48074d4532b913a940b551f4624fd00309c8f5d2a9775350430b143277b1dfe8064fd899a58408d9

diff --git a/sci-mathematics/bertini/bertini-1.6.ebuild b/sci-mathematics/bertini/bertini-1.6.ebuild
new file mode 100644
index 000000000000..5fe2bd594d0f
--- /dev/null
+++ b/sci-mathematics/bertini/bertini-1.6.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MYP=BertiniSource_v${PV}
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Software for Numerical Algebraic Geometry"
+HOMEPAGE="http://bertini.nd.edu"
+SRC_URI="https://bertini.nd.edu/${MYP}.tar.gz
+	doc? ( https://bertini.nd.edu/BertiniUsersManual.pdf )"
+S="${WORKDIR}"/${MYP/./}
+
+LICENSE="bertini"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples +optimization"
+
+RDEPEND="
+	dev-libs/gmp
+	dev-libs/mpfr
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+
+	# bug #723328
+	append-cflags -fcommon
+
+	# Ensure this is before the CFLAGS sed
+	# or breakage occurs if 'gcc' is in your CFLAGS
+	sed -i -e "s/gcc/$(tc-getCC)/" src/Makefile || die
+
+	if ! use optimization ; then
+		sed -i -e "s/\$(OPT)/ ${CFLAGS} ${CXXFLAGS} ${LDFLAGS}/" src/Makefile || die
+	else
+		# If people want the optimisation offered by upstream,
+		# let's ensure they don't accidentally override it.
+		filter-flags -O?
+		sed -i -e "s/\$(OPT)/ \$(OPT) ${CFLAGS} ${LDFLAGS}/" src/Makefile || die
+	fi
+}
+
+src_configure() {
+	econf --prefix=/usr --includedir=/usr/include/${PN}
+
+	use doc && DOCS+=( "${DISTDIR}"/BertiniUsersManual.pdf )
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	find "${ED}" -name "*.la" -delete || die
+
+	einstalldocs
+}