[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     04546306dffb5d39cee09808c5cbb2e8a60514f7
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 19 16:51:06 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Feb 19 17:14:04 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=04546306

dev-python/django: Bump to 3.0.13

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest             |   2 +
 dev-python/django/django-3.0.13.ebuild | 102 +++++++++++++++++++++++++++++++++
 2 files changed, 104 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 5bbc0269b35..5fb8ee7bc36 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,5 +4,7 @@ DIST Django-2.2.19.checksum.txt 2563 BLAKE2B 746ba6ba9ea4edba7641e8f32c6022be76b
 DIST Django-2.2.19.tar.gz 9209434 BLAKE2B 0928a06d467ba9d643693cf6ffba358c05a739c6dca6199853a4debeb064748c8c56d57b768eb283ccd9cc4afe5fc192636d8270aec93108b4bcce57be5003ed SHA512 92f2200f147766349526d21b5240307e4f082f97fc5b80b55777330068a9da5eaa9941360ccdd729573d015d9a7a0430461f1ac61f749a0475c006981d8775ea
 DIST Django-3.0.12.checksum.txt 2556 BLAKE2B 9012a130029c6fe73ace78fbdd32f1653bb7a7e84c343c394acc5563b7de9b5d6ec58734fdf79f2e7657f18644dd3a12c12c4a400a1002ad74d0891738ef4137 SHA512 46e7291f4d73472a118ff3aca4f597d6abde4a4217bb95ed84fda91efd0ed63e946d9ddf35ae65ff1e898462aebc32a3a43241f261099b17667958412d5afb32
 DIST Django-3.0.12.tar.gz 9255277 BLAKE2B 68be34ddad965bacca6bfcf045b5ab4072ef8a17f09acc674d2b5535b074d90c6881fd22edd89bdc82eefc90a2e7f561a041f9da066b85c13b10866f731a6106 SHA512 7f21a1a88a8c57d3b6ffa1a39e0df491e45f4e37181c4951db2a330266bf3ed8bf4e240a69a9b627dbbb090816c991b877b777e35b1c252a5ee08680eb3b0135
+DIST Django-3.0.13.checksum.txt 2563 BLAKE2B ef243cc9621c73ebf84e47292a18a41309eb51464a57a48084a3bfc086f9d9065c94d935136c47e0cd0f01243c4c49036a2bdaa96aac45389d25f1e085598ed7 SHA512 be4768c8ce5dddb26edfd4385da11eba9be3814bd58da6c74354d044860f6cc8805b1533169030c4a8d411d27152d40b5c7f067458dda9a11d893acd5c160baa
+DIST Django-3.0.13.tar.gz 9285769 BLAKE2B 9be51ec02119b79baa4f107f296c8b72920449eb846c3cd686b0d20417330eed4db1beedaaa3778ba45e0685cc4210325a4fdf04a979a028ad5360b9f160da09 SHA512 af4e4d1491ccd7edb4363f55a78f39850b55b544cceabaf8d94a3a7a866d29a63badfb41c834cefad3cadae612f2b074f9deacde5c5ee183c55f853c687c730c
 DIST Django-3.1.6.checksum.txt 2547 BLAKE2B 509254e5d24cdddfb452d922554db12a16ee1c5840d61d17f57c7b209aa71e3b8c8279efec35508cafd059836601d85bca16a33c618b466c438fc323bcbab720 SHA512 d9dd2763285ae9da7cf24bff957ed2cc78ab088fa34ad45fe176bd869fb892a0e50d2b67fb6a0fcda08f85c68602a3b1f76c265e3776d762f2ee1f96f0dd116f
 DIST Django-3.1.6.tar.gz 9645871 BLAKE2B 96269d5977d422e62637a956ea8b1af7abc4647350aa4c913e986a7104843d2a4d6c6425deabe2358e819692a721caa18002448b780d4384493bf9078bfbabd1 SHA512 fe5baef4aee51cc84292d1f4d3681cff8170c1307aa172b86faa15771af2c3e0b4dbb24ae671ad8ed31c53ab38ed99c64b5deb69d77fc268d8a232f3463c3221

diff --git a/dev-python/django/django-3.0.13.ebuild b/dev-python/django/django-3.0.13.ebuild
new file mode 100644
index 00000000000..c5e25f2be57
--- /dev/null
+++ b/dev-python/django/django-3.0.13.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/asgiref[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( app-crypt/openpgp-keys-django )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.6-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# do not bind to a specific version
+	# https://bugs.gentoo.org/750695
+	sed -i -e 's:asgiref ~= 3.2:asgiref:' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Additional Backend support can be enabled via"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	elog
+	elog "Other features can be enhanced by"
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}