[gentoo-commits] repo/gentoo:master commit in: net-wireless/lorcon/

["Rick Farina" <zerochaos@gentoo.org>]

commit:     9b738ecd8367a8e9138bbe068f4e4bda80c4132f
Author:     Rick Farina <zerochaos <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 17 16:01:22 2021 +0000
Commit:     Rick Farina <zerochaos <AT> gentoo <DOT> org>
CommitDate: Wed Feb 17 16:10:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9b738ecd

net-wireless/lorcon: bump

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Rick Farina <zerochaos <AT> gentoo.org>

 net-wireless/lorcon/Manifest                 |  1 +
 net-wireless/lorcon/lorcon-2020.06.06.ebuild | 70 ++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/net-wireless/lorcon/Manifest b/net-wireless/lorcon/Manifest
index 7aa71a54d79..39bee0406da 100644
--- a/net-wireless/lorcon/Manifest
+++ b/net-wireless/lorcon/Manifest
@@ -1 +1,2 @@
 DIST lorcon-0.0_p20200214.tar.gz 506444 BLAKE2B 07faf66dad8acae5cd2c1ff60778a1c6a7116be449740d975dc79e0606c646cf2fd21f3b5752d8fc6d23848347ce3ff9e14e0068a8f929a0b35434af7fef7fda SHA512 794a973ccccdd2f214041373ecb1ac167698e4cdf23b69900ba9e589fd88bdb064105ceb6c23ebd1d499db83ad7f417e1cbc4cd26169f46636cee2eb4764e28a
+DIST lorcon-2020.06.06.tar.gz 506144 BLAKE2B 6fe0d3578b8f91ed9ed0ea12ce110afc6764b694c78c57935b835e4fb8e4c4c81e07f7a8b069583382e91ef760a07bdcf3f9aa51167add052ac1f3f8c0758155 SHA512 1f51dc221d01356b59fd615ebccabb6d00f1999fd9450f6f092f6234635e162f0407e203df9dde4f0f942691cd9395df30377478ec677c910c2d1603228cef30

diff --git a/net-wireless/lorcon/lorcon-2020.06.06.ebuild b/net-wireless/lorcon/lorcon-2020.06.06.ebuild
new file mode 100644
index 00000000000..20a4da50162
--- /dev/null
+++ b/net-wireless/lorcon/lorcon-2020.06.06.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9})
+DISTUTILS_OPTIONAL=1
+
+inherit distutils-r1
+
+DESCRIPTION="A generic library for injecting 802.11 frames"
+HOMEPAGE="https://github.com/kismetwireless/lorcon"
+
+if [[ ${PV} == "9999" ]] ; then
+	#EGIT_REPO_URI="https://www.kismetwireless.net/lorcon.git"
+	EGIT_REPO_URI="https://github.com/kismetwireless/lorcon.git"
+	inherit git-r3
+	S="${WORKDIR}"/${P}
+else
+	SRC_URI="https://github.com/kismetwireless/lorcon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="python"
+
+DEPEND="
+	python? ( ${PYTHON_DEPS} )
+	dev-libs/libnl:3=
+	net-libs/libpcap"
+RDEPEND="${DEPEND}"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test"
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git-r3_src_unpack
+		cp -R "${S}/" "${WORKDIR}/all"
+	fi
+	default_src_unpack
+}
+
+src_prepare() {
+	default
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_compile() {
+	default_src_compile
+	if use python; then
+		LDFLAGS+=" -L${S}/.libs/"
+		cd pylorcon2 || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+	if use python; then
+		cd pylorcon2 || die
+		distutils-r1_src_install
+	fi
+	find "${ED}" -name '*.la' -delete || die
+}