[gentoo-commits] repo/gentoo:master commit in: media-libs/graphene/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     9a5060f3fc75bcb27ac845c146beea527eb54665
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Wed Feb 10 08:43:40 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sat Feb 13 21:21:42 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a5060f3

media-libs/graphene: python3_9

Closes: https://github.com/gentoo/gentoo/pull/19399
Closes: https://bugs.gentoo.org/760510
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 media-libs/graphene/graphene-1.10.2-r1.ebuild | 57 +++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/media-libs/graphene/graphene-1.10.2-r1.ebuild b/media-libs/graphene/graphene-1.10.2-r1.ebuild
new file mode 100644
index 00000000000..0de3c1124ed
--- /dev/null
+++ b/media-libs/graphene/graphene-1.10.2-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit xdg-utils meson multilib-minimal python-any-r1
+
+DESCRIPTION="A thin layer of types for graphic libraries"
+HOMEPAGE="https://ebassi.github.io/graphene/"
+SRC_URI="https://github.com/ebassi/graphene/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="cpu_flags_arm_neon cpu_flags_x86_sse2 doc +introspection test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.30.0:2[${MULTILIB_USEDEP}]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+# Python is only needed with USE=introspection or FEATURES=test, but not bothering with conditional python_setup, as meson uses it too anyway
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	# TODO: Do we want G_DISABLE_ASSERT as buildtype=release would do upstream?
+	local emesonargs=(
+		-Dgtk_doc=$(multilib_native_usex doc true false)
+		-Dgobject_types=true
+		-Dintrospection=$(multilib_native_usex introspection true false)
+		-Dgcc_vector=true # if built-in support tests fail, it'll just not enable vector intrinsics; unfortunately this probably means disabled on clang too, due to it claiming to be <gcc-4.9
+		$(meson_use cpu_flags_x86_sse2 sse2)
+		$(meson_use cpu_flags_arm_neon arm_neon)
+		$(meson_use test tests)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}