From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1250234-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 481FE1382C5
for <garchives@archives.gentoo.org>; Fri, 12 Feb 2021 02:15:35 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 6C79BE0B94;
Fri, 12 Feb 2021 02:15:33 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 427DDE0B94
for <gentoo-commits@lists.gentoo.org>; Fri, 12 Feb 2021 02:15:33 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id C9821340EC9
for <gentoo-commits@lists.gentoo.org>; Fri, 12 Feb 2021 02:15:31 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 34B704C7
for <gentoo-commits@lists.gentoo.org>; Fri, 12 Feb 2021 02:15:30 +0000 (UTC)
From: "Georgy Yakovlev" <gyakovlev@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Georgy Yakovlev" <gyakovlev@gentoo.org>
Message-ID: <1613093994.32ee81bf04a5ee942473075b40e4f94c0326a1a6.gyakovlev@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-java/openjdk-jre-bin/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-java/openjdk-jre-bin/Manifest dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.10_p9.ebuild
X-VCS-Directories: dev-java/openjdk-jre-bin/
X-VCS-Committer: gyakovlev
X-VCS-Committer-Name: Georgy Yakovlev
X-VCS-Revision: 32ee81bf04a5ee942473075b40e4f94c0326a1a6
X-VCS-Branch: master
Date: Fri, 12 Feb 2021 02:15:30 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 814f9f82-ab87-4085-8cba-e927b753a317
X-Archives-Hash: 1448bb77839a18cfbde93cb5acdebb95
commit: 32ee81bf04a5ee942473075b40e4f94c0326a1a6
Author: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 12 01:39:54 2021 +0000
Commit: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Fri Feb 12 01:39:54 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=32ee81bf
dev-java/openjdk-jre-bin: bump to 11.0.10_p9
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>
dev-java/openjdk-jre-bin/Manifest | 1 +
.../openjdk-jre-bin-11.0.10_p9.ebuild | 97 ++++++++++++++++++++++
2 files changed, 98 insertions(+)
diff --git a/dev-java/openjdk-jre-bin/Manifest b/dev-java/openjdk-jre-bin/Manifest
index 372a3c00dc4..41a00eb9303 100644
--- a/dev-java/openjdk-jre-bin/Manifest
+++ b/dev-java/openjdk-jre-bin/Manifest
@@ -1,2 +1,3 @@
+DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.10_9.tar.gz 43146855 BLAKE2B eab22a4134dd94143adc5f6da6932d015874ec1ae58fda927279c85190b9c90a13de2c08e9f1d6d2d91f9c13f3999d2e76b8fd511c17f66e4d18f687d0bc2047 SHA512 2cb56a58aa9c0644374d437d20eb908a8a997f6b8e49e4a3589e4d79d0d15eb4dc574e815cbba2cffce62e4e20fefec706e0c4a76d42212e10365ed90f8b6263
DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.9_11.tar.gz 43086814 BLAKE2B 20785b5edb3fbfae99c7cdc76fba964a7a00eb148e68125138281c0995d6a82cfe9924c7f653dd188ab97da41135004546ec822bfa845f599135c8a9ec5e9336 SHA512 b0c53febc2628b91763cd5304cce782adaa71ff466c4dd9d056c7f1ac18e8f1f4ad2fc355882b2990fbd71e7792134697bcd1204eb9e03c12cf3b287ac33c3f0
DIST OpenJDK8U-jre_x64_linux_hotspot_8u272b10.tar.gz 42139854 BLAKE2B 52e7a594aab1a70d351daf9dc42598b4952894a9a72ed996e261e347eece4337fe95c5f63850a0dde2d8862045d22ef41832a6af51df5113b81713bab20c797e SHA512 2fd45a9b967e96309c79724fea047d7c35f31da8e0290bd5cdafeea47b83941b9269129d0d557ee488526c0667ba581dee860381fc344374971e1005105db376
diff --git a/dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.10_p9.ebuild b/dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.10_p9.ebuild
new file mode 100644
index 00000000000..441b2550e44
--- /dev/null
+++ b/dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.10_p9.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit java-vm-2
+
+abi_uri() {
+ echo "${2-$1}? (
+ https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk-${MY_PV}/OpenJDK${SLOT}U-jre_${1}_linux_hotspot_${MY_PV//+/_}.tar.gz
+ )"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+ $(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="alsa cups +gentoo-vm headless-awt selinux"
+
+RDEPEND="
+ media-libs/fontconfig:1.0
+ media-libs/freetype:2
+ >net-libs/libnet-1.1
+ >=sys-apps/baselayout-java-0.1.0-r1
+ >=sys-libs/glibc-2.2.5:*
+ sys-libs/zlib
+ alsa? ( media-libs/alsa-lib )
+ cups? ( net-print/cups )
+ selinux? ( sec-policy/selinux-java )
+ !headless-awt? (
+ x11-libs/libX11
+ x11-libs/libXext
+ x11-libs/libXi
+ x11-libs/libXrender
+ x11-libs/libXtst
+ )"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}-jre"
+
+src_install() {
+ local dest="/opt/${P}"
+ local ddest="${ED%/}/${dest#/}"
+
+ # Not sure why they bundle this as it's commonly available and they
+ # only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+ # also has an explicit dependency while Oracle seemingly dlopens it.
+ rm -vf lib/libfreetype.so || die
+
+ # Oracle and IcedTea have libjsoundalsa.so depending on
+ # libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+ if ! use alsa ; then
+ rm -v lib/libjsound.* || die
+ fi
+
+ if use headless-awt ; then
+ rm -v lib/lib*{[jx]awt,splashscreen}* || die
+ fi
+
+ rm -v lib/security/cacerts || die
+ dosym ../../../../etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+ dodir "${dest}"
+ cp -pPR * "${ddest}" || die
+
+ # provide stable symlink
+ dosym "${P}" "/opt/${PN}-${SLOT}"
+
+ use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+ java-vm_set-pax-markings "${ddest}"
+ java-vm_revdep-mask
+ java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+ java-vm-2_pkg_postinst
+
+ if use gentoo-vm ; then
+ ewarn "WARNING! You have enabled the gentoo-vm USE flag, making this JRE"
+ ewarn "recognised by the system. This will almost certainly break things."
+ else
+ ewarn "The experimental gentoo-vm USE flag has not been enabled so this JRE"
+ ewarn "will not be recognised by the system. For example, simply calling"
+ ewarn "\"java\" will launch a different JVM. This is necessary until Gentoo"
+ ewarn "fully supports Java 11. This JRE must therefore be invoked using its"
+ ewarn "absolute location under ${EPREFIX}/opt/${P}."
+ fi
+}