[gentoo-commits] repo/gentoo:master commit in: dev-libs/libevocosm/

["Sam James" <sam@gentoo.org>]

commit:     3a82cde2b556a7c0e3ff99a7384a95da91f20d34
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 10 21:59:40 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Feb 10 22:03:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3a82cde2

dev-libs/libevocosm: port to EAPI 7

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libevocosm/libevocosm-3.3.1-r1.ebuild | 33 +++++++++++++-------------
 1 file changed, 17 insertions(+), 16 deletions(-)

diff --git a/dev-libs/libevocosm/libevocosm-3.3.1-r1.ebuild b/dev-libs/libevocosm/libevocosm-3.3.1-r1.ebuild
index 877fc757d40..310e22a38db 100644
--- a/dev-libs/libevocosm/libevocosm-3.3.1-r1.ebuild
+++ b/dev-libs/libevocosm/libevocosm-3.3.1-r1.ebuild
@@ -1,9 +1,7 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-
-inherit eutils ltprune
+EAPI=7
 
 DESCRIPTION="A C++ framework for evolutionary computing"
 HOMEPAGE="http://www.coyotegulch.com/products/libevocosm/"
@@ -12,37 +10,40 @@ SRC_URI="http://www.coyotegulch.com/distfiles/${P}.tar.gz"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
 
-IUSE="doc static-libs"
-
+BDEPEND="doc? ( app-doc/doxygen )"
 RDEPEND="dev-libs/libcoyotl
 	dev-libs/libbrahe"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )"
+DEPEND="${RDEPEND}"
 
 DOCS=( AUTHORS ChangeLog NEWS README )
 
-src_prepare() {
-	epatch "${FILESDIR}/${P}-gcc47.patch"
-	epatch_user
-}
+PATCHES=(
+	"${FILESDIR}/${P}-gcc47.patch"
+)
 
 src_configure() {
 	export ac_cv_prog_HAVE_DOXYGEN="false"
-	econf $(use_enable static-libs static)
+	econf --disable-static
 }
 
 src_compile() {
 	emake
 
 	if use doc ; then
-		cd docs
+		cd docs || die
 		doxygen libevocosm.doxygen || die "generating docs failed"
 	fi
 }
 
 src_install() {
 	default
-	prune_libtool_files
-	use doc && dohtml docs/html/*
+
+	if use doc ; then
+		docinto html
+		dodoc docs/html/*
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
 }