[gentoo-commits] repo/gentoo:master commit in: media-video/shotcut/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     acafeeedbce3a385e8fd9b8f052f3e9e7f0ee294
Author:     Felix Neumärker <xdch47 <AT> posteo <DOT> de>
AuthorDate: Fri Jan  8 08:02:27 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Feb 10 14:55:08 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=acafeeed

media-video/shotcut: add live ebuild

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Felix Neumärker <xdch47 <AT> posteo.de>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-video/shotcut/shotcut-9999.ebuild | 60 +++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/media-video/shotcut/shotcut-9999.ebuild b/media-video/shotcut/shotcut-9999.ebuild
new file mode 100644
index 00000000000..598b4f6b656
--- /dev/null
+++ b/media-video/shotcut/shotcut-9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils xdg
+
+DESCRIPTION="A free, open source, cross-platform video editor"
+HOMEPAGE="https://www.shotcut.org/ https://github.com/mltframework/shotcut/"
+if [[ ${PV} != 9999* ]] ; then
+	SRC_URI="https://github.com/mltframework/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mltframework/shotcut/"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5[widgets]
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsql:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	>=media-libs/mlt-6.22.1[ffmpeg,frei0r,fftw,jack,melt(+),opengl,qt5,sdl,xml]
+	media-video/ffmpeg
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/qtx11extras:5
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-qt/qtgraphicaleffects:5
+	dev-qt/qtquickcontrols:5
+	virtual/jack
+"
+
+src_configure() {
+	eqmake5 \
+		PREFIX="${EPREFIX}/usr" \
+		SHOTCUT_VERSION="${PV}" \
+		DEFINES+=SHOTCUT_NOUPGRADE
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}