[gentoo-commits] repo/gentoo:master commit in: media-gfx/darktable/

["Marek Szuba" <marecki@gentoo.org>]

commit:     cc54b6d6a29c269e0d70b83f91c9e2bade93608c
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  8 13:26:13 2021 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Mon Feb  8 13:47:58 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc54b6d6

media-gfx/darktable: bump to 3.4.1

Bugfix release.

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 media-gfx/darktable/Manifest               |   1 +
 media-gfx/darktable/darktable-3.4.1.ebuild | 177 +++++++++++++++++++++++++++++
 2 files changed, 178 insertions(+)

diff --git a/media-gfx/darktable/Manifest b/media-gfx/darktable/Manifest
index 5e5b30e791b..76cacfea9f2 100644
--- a/media-gfx/darktable/Manifest
+++ b/media-gfx/darktable/Manifest
@@ -2,6 +2,7 @@ DIST darktable-2.6.2-gcc9.patch.tar.xz 25864 BLAKE2B 857803d4c46b47b1e06e962533c
 DIST darktable-2.6.2.tar.xz 3512572 BLAKE2B ee3070ac0f6b6b1c401865801631fb28397f484f30778065b7f899204813530a47ff6e752504b645f59bc29f868e1498e39f5f4e70f8259d8fecf5abc3f15cd6 SHA512 e7a90535747a8615fa2dbd1eb05f81314cc61c689a8a85fda0e2be40208ab0248e6f6ef296bb0894d3d527ed47c6cf6640538029c0c2d58a38d2d5ce10f6f5c0
 DIST darktable-3.2.1.tar.xz 3920728 BLAKE2B 79ef5df93d6c4728d19bc8bf01d018f071efe1ea94a68be53fced7217df608e5362b9905e2e633af4d0a11574ca3e42eac9d97fd3bfaf3a22b45b61213f60070 SHA512 0c76f7c145b470d0b129e4565727cef0c7509c1cb7f2405e41b20c81411741513cfc2976c7b8fe168bc1b017e7bfc292bb2d824c3beddce6432ee7143513bdc7
 DIST darktable-3.4.0.tar.xz 4444452 BLAKE2B 98b717aafe940a6916a2c2c42577be4956a171e7b445d69d20cb6aa1db35a255919524e8547c229461c64022fa3df5ace57a9e7a5ed32304820d5f263c3acbfc SHA512 b0a1e58f9af4007b22bacd7c61c75bdd036db9b1bbb6bd0ed785759d1a7a5a095a49a2a68c1555c661c4fff2549fcd35d2db2d9d4c16fc035bb37939804c749f
+DIST darktable-3.4.1.tar.xz 4456192 BLAKE2B 7b573db69cb32496ad79d6636b50d3b2db471376c2486d356e1da2740d48644821265c3249a40603a521d588ef89cee33e31d7a6b216f106625ca2aa3f8bfb68 SHA512 3376c5e2aa52d02fcfc45d9efb1a60a7bee6210dc81e1131f2c163ca2059860f7e3a64b5cfd05117dcaaf8c7810d08a84058a0b64ef6fd24c90bbafde7ca4f6f
 DIST darktable-usermanual-2.6.0.pdf 15623135 BLAKE2B a7a254e49dd57ee03480d52f4506a436210324cc4a2651f3c2fd70ca65cb7aa1735934a5e046ffa662b2aa1f081042d2d1e6ce0f70b6768719c52e2d14c358ce SHA512 e68005ee8706f2342755ce3e4dcd6c2907c1607bc9b750154dceb4b52dcccf50c581ab65212efc8ffb2447f5d828e0fdb61d0471c3d14938e098528e50f32e14
 DIST darktable-usermanual-3.0.0.pdf 16237603 BLAKE2B ff5c24bb038deb37269a84389937740fa0ff77a9fb5bef4c484cdd903e39609588f632f577ce53c690d3abb832ace451d0d9d3f563ebdb6196ae8e2dac008a01 SHA512 2523b48e2baaa71561dc119340aed3bbf2ab4481dceb0c3ca2bbb7b0cacfaab894fa4eef82b667648cd7bb049304dbda09fa1a638f7734219b672b3ea8ee0eac
 DIST darktable-usermanual-3.4.0.pdf 16241791 BLAKE2B d6fc232c3eddb5474e36ce1fbc02c3472291e5ebdf2eae09c419215263f615546a79f88ee9d252b387fc5e4f2c9714398deab8de176b3d928b6a17c2878cef56 SHA512 fd154c02d5e0c63d9698b2f80a7439a191f4582b717b2f163923eda40aae1ebe8aeaf1a70efdc423eb8c8269d74fc0e23df8c9c0269ee8f5a357611501c3547e

diff --git a/media-gfx/darktable/darktable-3.4.1.ebuild b/media-gfx/darktable/darktable-3.4.1.ebuild
new file mode 100644
index 00000000000..c66c363f491
--- /dev/null
+++ b/media-gfx/darktable/darktable-3.4.1.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-3 )
+
+inherit cmake flag-o-matic lua-single toolchain-funcs xdg
+
+DESCRIPTION="A virtual lighttable and darkroom for photographers"
+HOMEPAGE="https://www.darktable.org/"
+LICENSE="GPL-3 CC-BY-3.0"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/darktable-org/${PN}.git"
+
+	LANGS=" af ca cs da de el es fi fr gl he hu it ja nb nl pl pt-BR pt-PT ro ru sk sl sq sv th uk zh-CN zh-TW"
+else
+	DOC_PV="3.4.0"
+	MY_PV="${PV/_/}"
+	MY_P="${P/_/.}"
+
+	SRC_URI="https://github.com/darktable-org/${PN}/releases/download/release-${MY_PV}/${MY_P}.tar.xz
+		doc? ( https://github.com/darktable-org/${PN}/releases/download/release-${DOC_PV}/${PN}-usermanual.pdf -> ${PN}-usermanual-${DOC_PV}.pdf )"
+
+	KEYWORDS="~amd64 ~arm64"
+	LANGS=" af cs de es fi fr he hu it pl pt-BR ru sk sl"
+fi
+
+IUSE="avif colord cups cpu_flags_x86_sse3 doc flickr geolocation gmic gnome-keyring gphoto2 graphicsmagick jpeg2k kwallet
+	lto lua nls opencl openmp openexr test tools webp
+	${LANGS// / l10n_}"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-python/jsonschema-3.2.0 )
+"
+COMMON_DEPEND="
+	dev-db/sqlite:3
+	dev-libs/json-glib
+	dev-libs/libxml2:2
+	>=dev-libs/pugixml-1.8:0=
+	gnome-base/librsvg:2
+	>=media-gfx/exiv2-0.25-r2:0=[xmp]
+	media-libs/lcms:2
+	>=media-libs/lensfun-0.2.3:0=
+	media-libs/libpng:0=
+	media-libs/tiff:0
+	net-libs/libsoup:2.4
+	net-misc/curl
+	sys-libs/zlib:=
+	virtual/jpeg:0
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/pango
+	avif? ( >=media-libs/libavif-0.8.2 )
+	colord? ( x11-libs/colord-gtk:0= )
+	cups? ( net-print/cups )
+	flickr? ( media-libs/flickcurl )
+	geolocation? ( >=sci-geosciences/osm-gps-map-1.1.0 )
+	gmic? ( media-gfx/gmic )
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	gphoto2? ( media-libs/libgphoto2:= )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lua? ( ${LUA_DEPS} )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	webp? ( media-libs/libwebp:0= )
+"
+DEPEND="${COMMON_DEPEND}
+	opencl? (
+		>=sys-devel/clang-4
+		>=sys-devel/llvm-4
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	kwallet? ( >=kde-frameworks/kwallet-5.34.0-r1 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/"${PN}"-find-opencl-header.patch
+	"${FILESDIR}"/${PN}-3.0.2_cmake-march-autodetection.patch
+	"${FILESDIR}"/${PN}-3.4.0_jsonschema-automagic.patch
+)
+
+S="${WORKDIR}/${P/_/~}"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		# Bug #695658
+		if tc-is-gcc; then
+			test-flags-CC -floop-block &> /dev/null || \
+				die "Please switch to a gcc version built with USE=graphite"
+		fi
+
+		if use openmp ; then
+			tc-has-openmp || die "Please switch to an openmp compatible compiler"
+		fi
+	fi
+}
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse3 && append-flags -msse3
+
+	sed -i -e 's:/appdata:/metainfo:g' data/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CURVE_TOOLS=$(usex tools)
+		-DBUILD_NOISE_TOOLS=$(usex tools)
+		-DBUILD_PRINT=$(usex cups)
+		-DCUSTOM_CFLAGS=ON
+		-DDONT_USE_INTERNAL_LUA=ON
+		-DRAWSPEED_ENABLE_LTO=$(usex lto)
+		-DUSE_AVIF=$(usex avif)
+		-DUSE_CAMERA_SUPPORT=$(usex gphoto2)
+		-DUSE_COLORD=$(usex colord)
+		-DUSE_FLICKR=$(usex flickr)
+		-DUSE_GMIC=$(usex gmic)
+		-DUSE_GRAPHICSMAGICK=$(usex graphicsmagick)
+		-DUSE_KWALLET=$(usex kwallet)
+		-DUSE_LIBSECRET=$(usex gnome-keyring)
+		-DUSE_LUA=$(usex lua)
+		-DUSE_MAP=$(usex geolocation)
+		-DUSE_NLS=$(usex nls)
+		-DUSE_OPENCL=$(usex opencl)
+		-DUSE_OPENEXR=$(usex openexr)
+		-DUSE_OPENJPEG=$(usex jpeg2k)
+		-DUSE_OPENMP=$(usex openmp)
+		-DUSE_WEBP=$(usex webp)
+		-DWANT_JSON_VALIDATION=$(usex test)
+	)
+	CMAKE_BUILD_TYPE="RELWITHDEBINFO"
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# This USE flag is masked for -9999
+	use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${DOC_PV}.pdf
+
+	if use nls; then
+		for lang in ${LANGS} ; do
+			if ! use l10n_${lang}; then
+				rm -r "${ED}"/usr/share/locale/${lang/-/_} || die
+			fi
+		done
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog
+	elog "When updating a major version,"
+	elog "please bear in mind that your edits will be preserved during this process,"
+	elog "but it will not be possible to downgrade any more."
+	elog
+	ewarn "It will not be possible to downgrade!"
+	ewarn
+}