[gentoo-commits] repo/gentoo:master commit in: gnome-extra/nm-applet/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     5c986ec2368af96cc350bf1ba38cc6c3e7d59f95
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  6 09:56:49 2021 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Feb  6 09:57:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5c986ec2

gnome-extra/nm-applet: bump to 1.20.0

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/nm-applet/Manifest                |  1 +
 gnome-extra/nm-applet/nm-applet-1.20.0.ebuild | 52 +++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/gnome-extra/nm-applet/Manifest b/gnome-extra/nm-applet/Manifest
index 2f3267e9799..40e25a34202 100644
--- a/gnome-extra/nm-applet/Manifest
+++ b/gnome-extra/nm-applet/Manifest
@@ -1 +1,2 @@
 DIST network-manager-applet-1.18.0.tar.xz 1950696 BLAKE2B d89f4d3c94af2c6bf514fc388fc445415b50508bf7e26f7888d8e212a63879abb24bf860002372bcae71eee94c3b8e9f2bfa9f16814a3537b0f81c486f82e396 SHA512 adca7c723600ec1cb2eed0110e369cf707fde1d64a81489440a167516d178a501fe883c08db06371b8aac896188eb2037a7577ecca721d764be33f4025a386d4
+DIST network-manager-applet-1.20.0.tar.xz 1953772 BLAKE2B 1fb480887e61d7ef3a76ac5ded7ffe6723e99b2ae53d2a53990d3c2617eac45bc99b00b10b43929e8696488abc1b0be2194e800b931732f229d7d4bd17e1951e SHA512 3b7ffd61e4f810fedee5aaf64725fcc2a8ee3c6b776f2d0b93f337c207516392b4720acea35c56c80755842c600edb971a67813c1583c112a91496d3d8db2c67

diff --git a/gnome-extra/nm-applet/nm-applet-1.20.0.ebuild b/gnome-extra/nm-applet/nm-applet-1.20.0.ebuild
new file mode 100644
index 00000000000..9a0c4cf3048
--- /dev/null
+++ b/gnome-extra/nm-applet/nm-applet-1.20.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GNOME_ORG_MODULE="network-manager-applet"
+
+inherit gnome.org meson xdg
+
+DESCRIPTION="NetworkManager connection editor and applet"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="appindicator modemmanager selinux teamd"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=app-crypt/libsecret-0.18
+	>=net-libs/libnma-1.8.27
+	>=x11-libs/gtk+-3.10:3
+	>=dev-libs/libgudev-147:=
+	>=x11-libs/libnotify-0.7.0
+	>=net-misc/networkmanager-1.16:=[modemmanager?,teamd?]
+	appindicator? (
+		dev-libs/libappindicator:3
+		>=dev-libs/libdbusmenu-16.04.0
+	)
+	modemmanager? ( net-misc/modemmanager )
+	selinux? ( sys-libs/libselinux )
+	teamd? ( >=dev-libs/jansson-2.7 )
+
+	virtual/freedesktop-icon-theme
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dappindicator=$(usex appindicator ubuntu no)
+		$(meson_use modemmanager wwan)
+		$(meson_use selinux)
+		$(meson_use teamd team)
+		-Dmore_asserts=0
+		-Dld_gc=false
+	)
+	meson_src_configure
+}