[gentoo-commits] repo/gentoo:master commit in: x11-themes/gtk-engines-unico/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     3a22e1e18d5239c0cb3d9545a89188aa9dd3cd7c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 24 15:28:59 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Jan 24 15:46:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3a22e1e1

x11-themes/gtk-engines-unico: EAPI-7++, autotools-multilib--

Drop superfluous eutils.

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../gtk-engines-unico-1.0.3_pre20140109-r1.ebuild  | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/x11-themes/gtk-engines-unico/gtk-engines-unico-1.0.3_pre20140109-r1.ebuild b/x11-themes/gtk-engines-unico/gtk-engines-unico-1.0.3_pre20140109-r1.ebuild
new file mode 100644
index 00000000000..f2451ccc2fa
--- /dev/null
+++ b/x11-themes/gtk-engines-unico/gtk-engines-unico-1.0.3_pre20140109-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=${PN/gtk-engines-}
+MY_PV=${PV/_pre/+14.04.}
+MY_P=${MY_PN}_${MY_PV}
+inherit autotools multilib-minimal
+
+DESCRIPTION="The Unico GTK+ 3.x theming engine"
+HOMEPAGE="https://launchpad.net/unico"
+SRC_URI="https://launchpad.net/ubuntu/+archive/primary/+files/${MY_P}.orig.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}]
+	>=x11-libs/cairo-1.10[glib,${MULTILIB_USEDEP}]
+	>=x11-libs/gtk+-3.5.2:3[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# $(use_enable debug) controls CPPFLAGS -D_DEBUG and -DNDEBUG but they are currently
+	# unused in the code itself.
+	local myeconfargs=(
+		--disable-static
+		--disable-debug
+		--disable-maintainer-flags
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name '*.la' -delete || die
+}