[gentoo-commits] repo/gentoo:master commit in: dev-libs/dbus-c++/

["David Seifert" <soap@gentoo.org>]

commit:     423a5e1fdb94b3f6d9d3ca0de14764c773b56530
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 23 23:37:51 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Jan 23 23:37:51 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=423a5e1f

dev-libs/dbus-c++: Port to EAPI 7

Closes: https://bugs.gentoo.org/624596
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 dev-libs/dbus-c++/dbus-c++-0.9.0-r4.ebuild | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/dev-libs/dbus-c++/dbus-c++-0.9.0-r4.ebuild b/dev-libs/dbus-c++/dbus-c++-0.9.0-r4.ebuild
new file mode 100644
index 00000000000..0c861a1221b
--- /dev/null
+++ b/dev-libs/dbus-c++/dbus-c++-0.9.0-r4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="Provides a C++ API for D-BUS"
+HOMEPAGE="https://sourceforge.net/projects/dbus-cplusplus/ https://sourceforge.net/apps/mediawiki/dbus-cplusplus/index.php?title=Main_Page"
+SRC_URI="mirror://sourceforge/dbus-cplusplus/lib${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc ecore glib test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	ecore? ( dev-libs/efl )
+	glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-util/cppunit[${MULTILIB_USEDEP}]"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/lib${P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc-4.7.patch #424707
+	"${FILESDIR}"/${PN}-gcc7.patch #622790
+)
+
+multilib_src_configure() {
+	# TODO : add ecore multilib support if/when it is multilibified
+	ECONF_SOURCE="${S}" econf \
+		--disable-examples \
+		--disable-static \
+		$(multilib_native_use_enable doc doxygen-docs) \
+		$(multilib_native_use_enable ecore) \
+		$(use_enable glib) \
+		$(use_enable test tests) \
+		PTHREAD_LIBS=-lpthread
+	# ACX_PTHREAD sets PTHREAD_CFLAGS but not PTHREAD_LIBS for some reason...
+
+	if multilib_is_native_abi; then
+		# docs don't like out-of-source builds
+		local d
+		for d in img html; do
+			ln -s "${S}"/doc/${d} "${BUILD_DIR}"/doc/${d} || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( doc/html/. )
+	einstalldocs
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}