[gentoo-commits] repo/gentoo:master commit in: media-libs/libcanberra/

["Matt Turner" <mattst88@gentoo.org>]

commit:     f1ca05b2313d5e1c889011acd727bbba6ccffe99
Author:     David Michael <fedora.dm0 <AT> gmail <DOT> com>
AuthorDate: Sat Dec 26 02:37:02 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Jan 18 21:09:56 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1ca05b2

media-libs/libcanberra: EAPI 7

Signed-off-by: David Michael <fedora.dm0 <AT> gmail.com>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-libs/libcanberra/libcanberra-0.30-r5.ebuild | 22 +++++++++++-----------
 1 file changed, 11 insertions(+), 11 deletions(-)

diff --git a/media-libs/libcanberra/libcanberra-0.30-r5.ebuild b/media-libs/libcanberra/libcanberra-0.30-r5.ebuild
index dd0bace15bf..344dbc29587 100644
--- a/media-libs/libcanberra/libcanberra-0.30-r5.ebuild
+++ b/media-libs/libcanberra/libcanberra-0.30-r5.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="5"
-inherit autotools-multilib eutils ltprune systemd
+EAPI=7
+inherit multilib-minimal systemd
 
 DESCRIPTION="Portable sound event library"
 HOMEPAGE="http://git.0pointer.net/libcanberra.git/"
@@ -13,7 +13,7 @@ SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
 IUSE="alsa gnome gstreamer +gtk +gtk3 oss pulseaudio +sound tdb udev"
 
-COMMON_DEPEND="
+DEPEND="
 	dev-libs/libltdl:0[${MULTILIB_USEDEP}]
 	media-libs/libvorbis[${MULTILIB_USEDEP}]
 	alsa? (
@@ -31,22 +31,22 @@ COMMON_DEPEND="
 	pulseaudio? ( >=media-sound/pulseaudio-0.9.11[${MULTILIB_USEDEP}] )
 	tdb? ( sys-libs/tdb:=[${MULTILIB_USEDEP}] )
 "
-RDEPEND="${COMMON_DEPEND}
+RDEPEND="${DEPEND}
 	gnome? (
 		gnome-base/dconf
 		gnome-base/gsettings-desktop-schemas )
 	sound? ( x11-themes/sound-theme-freedesktop )" # Required for index.theme wrt #323379
-DEPEND="${COMMON_DEPEND}
+BDEPEND="
 	app-arch/xz-utils
 	virtual/pkgconfig
 "
 
 REQUIRED_USE="udev? ( alsa )"
 
-src_prepare() {
+PATCHES=(
 	# gtk: Don't assume all GdkDisplays are GdkX11Displays: broadway/wayland (from 'master')
-	epatch "${FILESDIR}/${PN}-0.30-wayland.patch"
-}
+	"${FILESDIR}/${PN}-0.30-wayland.patch"
+)
 
 multilib_src_configure() {
 	ECONF_SOURCE="${S}" econf \
@@ -59,9 +59,9 @@ multilib_src_configure() {
 		$(use_enable gtk3) \
 		$(use_enable tdb) \
 		$(use_enable udev) \
-		$(systemd_with_unitdir) \
 		--disable-lynx \
-		--disable-gtk-doc
+		--disable-gtk-doc \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
 
 	if multilib_is_native_abi; then
 		ln -s "${S}"/gtkdoc/html gtkdoc/html || die
@@ -75,7 +75,7 @@ multilib_src_install() {
 
 multilib_src_install_all() {
 	einstalldocs
-	prune_libtool_files --modules
+	find "${ED}" -type f -name '*.la' -delete || die
 
 	# This is needed for desktops different than GNOME, bug #520550
 	exeinto /etc/X11/xinit/xinitrc.d