[gentoo-commits] repo/gentoo:master commit in: dev-libs/hyperscan/

["Sam James" <sam@gentoo.org>]

commit:     ed3ee17b0406d6841d33f51115c50c6463217f04
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Wed Jan 13 11:17:39 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jan 14 01:20:28 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ed3ee17b

dev-libs/hyperscan: bump to 5.4.0

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Closes: https://github.com/gentoo/gentoo/pull/19052
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/hyperscan/Manifest               |  1 +
 dev-libs/hyperscan/hyperscan-5.4.0.ebuild | 54 +++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/dev-libs/hyperscan/Manifest b/dev-libs/hyperscan/Manifest
index 1b136837059..dd7672155aa 100644
--- a/dev-libs/hyperscan/Manifest
+++ b/dev-libs/hyperscan/Manifest
@@ -1 +1,2 @@
 DIST hyperscan-5.3.0.tar.gz 1824077 BLAKE2B 6d1c8ac8df32e8e4ac09f51ad292e566c2af2b7de9fb1f0bf99b233b9647b527ea115b6bdace5533927bc7a0eace626921b391ad3e78d62fe54636ae13b9f26e SHA512 a4d85ffd2264e8e6745340ba51431361775a1e7a2da78edd31f6f53552ac61fdef718710ae53a254b7d5000f9ec1aafe7a48d9c55e76f5c6822486150bbc6c56
+DIST hyperscan-5.4.0.tar.gz 1844963 BLAKE2B 1a5af88655854b4c1ec58e6663b6c9c4b6fca0aa9d3e4daad3992daf911b8f359f48a95b65e4f05c71aa644e0271471d016fafaca05d547b838a9c52ea016e27 SHA512 cfec3f43b9e8b3fbb2e761927f3a173c1230f2688da710ec7708f2941ce6f550a1d3cb48b0b0e2ccf709807390117a7e40047cb99190bcc341f37eb3da13ae62

diff --git a/dev-libs/hyperscan/hyperscan-5.4.0.ebuild b/dev-libs/hyperscan/hyperscan-5.4.0.ebuild
new file mode 100644
index 00000000000..befb1587018
--- /dev/null
+++ b/dev-libs/hyperscan/hyperscan-5.4.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit cmake flag-o-matic python-any-r1
+
+DESCRIPTION="High-performance regular expression matching library"
+SRC_URI="https://github.com/intel/hyperscan/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="https://www.hyperscan.io/ https://github.com/intel/hyperscan"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_avx2 +cpu_flags_x86_ssse3 static-libs"
+
+RDEPEND="dev-libs/boost"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ragel
+"
+
+REQUIRED_USE="cpu_flags_x86_ssse3"
+
+src_prepare() {
+	# Respect user -O flags
+	sed -i '/set(OPT_CX*_FLAG/d' CMakeLists.txt || die
+
+	# upstream workaround
+	append-cxxflags -Wno-redundant-move
+	cmake_src_prepare
+}
+
+src_configure() {
+	CMAKE_BUILD_TYPE=Release
+
+	use cpu_flags_x86_ssse3 && append-flags -mssse3
+	use cpu_flags_x86_avx2  && append-flags -mavx2
+
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=$(usex static-libs OFF ON)
+		-DBUILD_STATIC_AND_SHARED=$(usex static-libs ON OFF)
+		-DBUILD_EXAMPLES=OFF
+		-DFAT_RUNTIME=false
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unit-hyperscan || die
+}