From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1240848-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 031481382C5
	for <garchives@archives.gentoo.org>; Sun, 10 Jan 2021 23:12:41 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 08C07E0AB0;
	Sun, 10 Jan 2021 23:12:40 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id CEF0AE0AB0
	for <gentoo-commits@lists.gentoo.org>; Sun, 10 Jan 2021 23:12:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 1EEB1340E3C
	for <gentoo-commits@lists.gentoo.org>; Sun, 10 Jan 2021 23:12:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 9D5D1309
	for <gentoo-commits@lists.gentoo.org>; Sun, 10 Jan 2021 23:12:36 +0000 (UTC)
From: "Erik Mackdanz" <stasibear@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Erik Mackdanz" <stasibear@gentoo.org>
Message-ID: <1610320260.3b80de6ee58f529844712762496055e98609dfbd.stasibear@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: games-roguelike/stone-soup/
X-VCS-Repository: repo/gentoo
X-VCS-Files: games-roguelike/stone-soup/Manifest games-roguelike/stone-soup/stone-soup-0.25.1-r101.ebuild
X-VCS-Directories: games-roguelike/stone-soup/
X-VCS-Committer: stasibear
X-VCS-Committer-Name: Erik Mackdanz
X-VCS-Revision: 3b80de6ee58f529844712762496055e98609dfbd
X-VCS-Branch: master
Date: Sun, 10 Jan 2021 23:12:36 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 566df3ff-9d8c-41a6-86d3-97f0474cf4ea
X-Archives-Hash: 081a4398e562abf29e029a9b922c23cc

commit:     3b80de6ee58f529844712762496055e98609dfbd
Author:     Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 10 22:35:52 2021 +0000
Commit:     Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
CommitDate: Sun Jan 10 23:11:00 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3b80de6e

games-roguelike/stone-soup: Implement slotting for major releases

Signed-off-by: Erik Mackdanz <stasibear <AT> gentoo.org>
Package-Manager: Portage-3.0.12, Repoman-3.0.2

 games-roguelike/stone-soup/Manifest                |   2 +
 .../stone-soup/stone-soup-0.25.1-r101.ebuild       | 184 +++++++++++++++++++++
 2 files changed, 186 insertions(+)

diff --git a/games-roguelike/stone-soup/Manifest b/games-roguelike/stone-soup/Manifest
index 2afbffc332e..cd8a61e8ec3 100644
--- a/games-roguelike/stone-soup/Manifest
+++ b/games-roguelike/stone-soup/Manifest
@@ -1,3 +1,5 @@
+DIST stone-soup-0.25.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
+DIST stone-soup-0.25.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
 DIST stone-soup.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
 DIST stone_soup-0.25.1.zip 95477710 BLAKE2B 0b38a6c7cb7c4c87acccb861b5aae665cd2b6b532f6e86d4a9fa594e0d363b86b4af1ea47275f7fd026ea69d85215be8cdf46258bd620e738b4850e5eceed006 SHA512 fa7e8be582c5c6615531884ade4c113542c06c164b6912095c1adf2f16a31cb2ecce057d74132b11b1b1c256a77433037948d4e54819739b7e222cc896cd5220

diff --git a/games-roguelike/stone-soup/stone-soup-0.25.1-r101.ebuild b/games-roguelike/stone-soup/stone-soup-0.25.1-r101.ebuild
new file mode 100644
index 00000000000..c843b3c00e0
--- /dev/null
+++ b/games-roguelike/stone-soup/stone-soup-0.25.1-r101.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# TODO
+# - attempt +test, linked bug claims to be fixed
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+VIRTUALX_REQUIRED="manual"
+inherit desktop python-any-r1 eutils lua-single xdg-utils toolchain-funcs
+
+MY_P="stone_soup-${PV}"
+DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
+HOMEPAGE="https://crawl.develz.org"
+SLOT="0.25"
+SRC_URI="
+	https://github.com/crawl/crawl/releases/download/${PV}/${PN/-/_}-${PV}.zip
+	https://dev.gentoo.org/~stasibear/distfiles/${PN}.png -> ${PN}-${SLOT}.png
+	https://dev.gentoo.org/~stasibear/distfiles/${PN}.svg -> ${PN}-${SLOT}.svg
+"
+
+# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
+# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
+# Public Domain|CC0: most of tiles
+# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
+LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug ncurses sound test +tiles"
+# test is broken
+# see https://crawl.develz.org/mantis/view.php?id=6121
+RESTRICT="test"
+
+RDEPEND="
+	${LUA_DEPS}
+	dev-db/sqlite:3
+	sys-libs/zlib
+	!ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
+	ncurses? ( sys-libs/ncurses:0 )
+	tiles? (
+		media-fonts/dejavu
+		media-libs/freetype:2
+		media-libs/libpng:0
+		sound? (
+			   media-libs/libsdl2[X,opengl,sound,video]
+			   media-libs/sdl2-mixer
+		)
+		!sound? ( media-libs/libsdl2[X,opengl,video] )
+		media-libs/sdl2-image[png]
+		virtual/glu
+		virtual/opengl
+	)"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-lang/perl
+	${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/flex
+	tiles? (
+		sys-libs/ncurses:0
+	)
+	virtual/pkgconfig
+	virtual/yacc
+	"
+
+S=${WORKDIR}/${MY_P}/source
+S_TEST=${WORKDIR}/${MY_P}_test/source
+PATCHES=(
+	"${FILESDIR}"/fixed-font-path.patch
+	"${FILESDIR}"/gitless-1.patch
+	"${FILESDIR}"/rltiles-ldflags-libs.patch
+)
+
+python_check_deps() {
+	has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+
+	python-any-r1_pkg_setup
+
+	if use !ncurses && use !tiles ; then
+		ewarn "Neither ncurses nor tiles frontend"
+		ewarn "selected, choosing ncurses only."
+		ewarn "Note that you can also enable both."
+	fi
+
+	if use sound && use !tiles ; then
+		ewarn "Sound support is only available with tiles."
+	fi
+}
+
+src_prepare() {
+	default
+	python_fix_shebang "${S}/util/species-gen.py"
+
+	sed -i -e "s/GAME = crawl$/GAME = crawl-${SLOT}/" "${S}/Makefile" \
+		|| die "Couldn't append slot to executable name"
+}
+
+src_compile() {
+
+	# Insurance that we're not using bundled lib sources
+	rm -rf contrib || die "Couldn't delete contrib directory"
+
+	export HOSTCXX=$(tc-getBUILD_CXX)
+
+	# leave DATADIR at the top
+	myemakeargs=(
+		$(usex debug "FULLDEBUG=y DEBUG=y" "")
+		BUILD_LUA=
+		AR="$(tc-getAR)"
+		CFOPTIMIZE=''
+		CFOTHERS="${CXXFLAGS}"
+		CONTRIBS=
+		DATADIR="/usr/share/${PN}-${SLOT}"
+		GCC="$(tc-getCC)"
+		GXX="$(tc-getCXX)"
+		LDFLAGS="${LDFLAGS}"
+		MAKEOPTS="${MAKEOPTS}"
+		PKGCONFIG="$(tc-getPKG_CONFIG)"
+		RANLIB="$(tc-getRANLIB)"
+		SAVEDIR="~/.crawl-${SLOT}"
+		SOUND=$(usex sound "y" "")
+		STRIP=touch
+		USE_LUAJIT=
+		V=1
+		prefix="/usr"
+	)
+
+	if use ncurses || (use !ncurses && use !tiles) ; then
+		emake "${myemakeargs[@]}"
+		# move it in case we build both variants
+		use tiles && { mv "crawl-${SLOT}" "${WORKDIR}"/crawl-ncurses-${SLOT} || die ;}
+	fi
+
+	if use tiles ; then
+		emake clean
+		emake "${myemakeargs[@]}" "TILES=y"
+	fi
+}
+
+src_install() {
+	emake "${myemakeargs[@]}" $(usex tiles "TILES=y" "") DESTDIR="${D}" prefix_fp="" bin_prefix="${D}/usr/bin" install
+	[[ -e "${WORKDIR}/crawl-ncurses-${SLOT}" ]] && dobin "${WORKDIR}/crawl-ncurses-${SLOT}"
+
+	# don't relocate docs, needed at runtime
+	rm -rf "${D}/usr/share/${PN}-${SLOT}"/docs/license
+
+	mv "${WORKDIR}/${MY_P}"/docs/crawl.6 "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6" \
+	   || die "Couldn't append slot to man page name"
+	doman "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6"
+
+	# icons and menu for graphical build
+	if use tiles ; then
+		doicon -s 48 "${DISTDIR}"/${PN}-${SLOT}.png
+		doicon -s scalable "${DISTDIR}"/${PN}-${SLOT}.svg
+		make_desktop_entry "crawl-${SLOT}" "crawl-${SLOT}" "crawl-${SLOT}"
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	elog "Since version 0.25.1-r101, crawl is a slotted install"
+	elog "that supports having multiple versions installed.  The"
+	elog "binary has the slot appened, e.g. 'crawl-"${SLOT}"'."
+	elog
+	elog "The local save directory also has the slot appended."
+	elog "If you have saved games from 0.25 but before 0.25.1-r101"
+	elog "you can 'mv ~/.crawl ~/.crawl-0.25' to fix it"
+
+	if use tiles && use ncurses ; then
+		elog
+		elog "Since you have enabled both tiles and ncurses frontends"
+		elog "the ncurses binary is called 'crawl-ncurses-"${SLOT}"' and the"
+		elog "tiles binary is called 'crawl-"${SLOT}"'."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}