[gentoo-commits] repo/gentoo:master commit in: media-gfx/gnome-screenshot/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3b3b3f87aa173cc9e1cc68d3a959198a9860dd2d
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 10 01:46:05 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Jan 10 02:16:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3b3b3f87

media-gfx/gnome-screenshot: Version bump to 3.38.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/gnome-screenshot/Manifest                |  1 +
 .../gnome-screenshot-3.38.0.ebuild                 | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/media-gfx/gnome-screenshot/Manifest b/media-gfx/gnome-screenshot/Manifest
index 329b57d7c9b..351c6e42634 100644
--- a/media-gfx/gnome-screenshot/Manifest
+++ b/media-gfx/gnome-screenshot/Manifest
@@ -1 +1,2 @@
 DIST gnome-screenshot-3.36.0.tar.xz 231420 BLAKE2B ce916d4d221252f47c84ebdec52ddcc2e25c2481df848cb6199842857c7ba537f56c22bdcb2a8e5b988d767fbc242d0c727119bc1ae9d569644eae15688aebf5 SHA512 fda599e7c50b37d8356352085b2f45f3b8c868af897352810998e127bd7333d5a1383369ec1cb980064f7e0aafa0e01bc5cdb31563ea56b1a7e4099fc18cc6b4
+DIST gnome-screenshot-3.38.0.tar.xz 356716 BLAKE2B 31f2a0cdf16a9f967c789ec1f698140f78a5c4d66489bc8a47b8b61b5e536e6b67fd60b9cb241221262eef5b3117ce3e1a59fa162a7f193de440f7de9db0afc3 SHA512 183f81b9b481d1afb4a3c8e37b25a78652e599d4c5a4f1a2cc9449cd1efdf3b613018c17de9ab61304ba19ad7152d696aeed475c0184a4728ea1359ca2be2ecf

diff --git a/media-gfx/gnome-screenshot/gnome-screenshot-3.38.0.ebuild b/media-gfx/gnome-screenshot/gnome-screenshot-3.38.0.ebuild
new file mode 100644
index 00000000000..9b96935da73
--- /dev/null
+++ b/media-gfx/gnome-screenshot/gnome-screenshot-3.38.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 xdg
+
+DESCRIPTION="Screenshot utility for GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-screenshot"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="X"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# libcanberra 0.26-r2 is needed for gtk+:3 fixes
+DEPEND="
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	>=dev-libs/glib-2.35.1:2[dbus]
+	>=x11-libs/gtk+-3.12.0:3
+	>=media-libs/libcanberra-0.26-r2[gtk3]
+	>=gui-libs/libhandy-1:1=
+"
+RDEPEND="${DEPEND}
+	>=gnome-base/gsettings-desktop-schemas-0.1.0
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+DOC_CONTENTS="${P} saves screenshots in ~/Pictures/ and defaults to
+	non-interactive mode when launched from a terminal. If you want to choose
+	where to save the screenshot, run 'gnome-screenshot --interactive'"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X x11)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}