From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1240015-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 586EF1382C5
for <garchives@archives.gentoo.org>; Fri, 8 Jan 2021 21:00:31 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 75EDEE01B5;
Fri, 8 Jan 2021 21:00:30 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 4B305E01B5
for <gentoo-commits@lists.gentoo.org>; Fri, 8 Jan 2021 21:00:30 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A95CA33BDF4
for <gentoo-commits@lists.gentoo.org>; Fri, 8 Jan 2021 21:00:28 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 1593C4C
for <gentoo-commits@lists.gentoo.org>; Fri, 8 Jan 2021 21:00:27 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1610139481.8b01d90f87e775581989627979c0ac7fa1795d23.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-print/cups-filters/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-print/cups-filters/Manifest net-print/cups-filters/cups-filters-1.28.7.ebuild
X-VCS-Directories: net-print/cups-filters/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 8b01d90f87e775581989627979c0ac7fa1795d23
X-VCS-Branch: master
Date: Fri, 8 Jan 2021 21:00:27 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 91a6863e-306e-44a6-8421-65db2e642f51
X-Archives-Hash: 7c790f27fa4c608320a4bb8a75fc57bc
commit: 8b01d90f87e775581989627979c0ac7fa1795d23
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 8 20:58:01 2021 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Jan 8 20:58:01 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b01d90f
net-print/cups-filters: Bump to version 1.28.7
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
net-print/cups-filters/Manifest | 1 +
net-print/cups-filters/cups-filters-1.28.7.ebuild | 148 ++++++++++++++++++++++
2 files changed, 149 insertions(+)
diff --git a/net-print/cups-filters/Manifest b/net-print/cups-filters/Manifest
index 576f48c6ae5..2ce49aa9269 100644
--- a/net-print/cups-filters/Manifest
+++ b/net-print/cups-filters/Manifest
@@ -2,3 +2,4 @@ DIST cups-filters-1.27.4.tar.xz 1493860 BLAKE2B 424c3ba73ec7d6f4683eaedde86d657b
DIST cups-filters-1.27.5.tar.xz 1494864 BLAKE2B 457968139f0bc1a5fd4c587dfe4a88d1904eb0ca9ee2aa88c1360785eb53b59e7eb823535ef01a9f81551628514441077562e91487a55a9f0c9e6c9dbdba98b7 SHA512 8bc917b2a168add1062d091d02d99c39d72861c0d0cb1242c34b2bf117c9943e7fdc1fe002de7cde4cb1919fbce41073adc34916c328fc99e66e389b0a4fe103
DIST cups-filters-1.28.2.tar.xz 1502352 BLAKE2B e0d95a7e1596d4dc05a8e2d32b2ee573cfa1ec304288e476a38c8b51de5ed8e0b6a71e371d2196802b116d63aea1e750e0b3a6c8fae749377de0ab72f92aa86e SHA512 aa5f075927286a8278259025aa5baf95445809a83b88e2d4654e8f0a124012591b045df115294242fae60a283d983d6cdbaafc6a51224af30a7e56b58d831da5
DIST cups-filters-1.28.3.tar.xz 1501824 BLAKE2B b4f493681ac2a701648b3b9b071f4ebfb432dd4660b610579ff2ed6cba4f6cd4351d5a1f28f5c096b3ba20d9c45dc87837bf127b9bc98680a98dec58dd0a68ea SHA512 ac139ae7452342bd46e464bff3438d437f1c9a2e719a7b32b7abc22c2667acaa93dfb976decb277a02572e688ecd86289e01fca817bef93018dff2076fb2a30c
+DIST cups-filters-1.28.7.tar.xz 1503052 BLAKE2B b9d3280871faa79a7c277731bf6eb1eef161537829d4bc07ec36075ebc12a3617dce66994ed708991757ce7d78fc5ab010925a1d3d9811fd11cf1172f4786442 SHA512 fa94f51ca1c208dcacb1814d8b812c9a72dd09475b7cf836b02c72cb5e3290318f37e475ee3ae8d45351715c3a2ccc0df5ac51ae6fc11462f5acdfa303a04727
diff --git a/net-print/cups-filters/cups-filters-1.28.7.ebuild b/net-print/cups-filters/cups-filters-1.28.7.ebuild
new file mode 100644
index 00000000000..7f74e5b5a9e
--- /dev/null
+++ b/net-print/cups-filters/cups-filters-1.28.7.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+GENTOO_DEPEND_ON_PERL=no
+
+inherit autotools perl-module systemd flag-o-matic
+
+if [[ "${PV}" == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/OpenPrinting/cups-filters.git"
+else
+ SRC_URI="http://www.openprinting.org/download/${PN}/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+fi
+DESCRIPTION="Cups filters"
+HOMEPAGE="https://wiki.linuxfoundation.org/openprinting/cups-filters"
+
+LICENSE="MIT GPL-2"
+SLOT="0"
+IUSE="dbus +foomatic jpeg ldap pclm pdf perl png +postscript static-libs test tiff zeroconf"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=app-text/poppler-0.32:=[cxx,jpeg?,lcms,tiff?,utils]
+ >=app-text/qpdf-8.3.0:=
+ dev-libs/glib:2
+ media-libs/fontconfig
+ media-libs/freetype:2
+ media-libs/lcms:2
+ >=net-print/cups-1.7.3
+ !<=net-print/cups-1.5.9999
+ sys-devel/bc
+ sys-libs/zlib
+ dbus? ( sys-apps/dbus )
+ foomatic? ( !net-print/foomatic-filters )
+ jpeg? ( virtual/jpeg:0 )
+ ldap? ( net-nds/openldap )
+ pdf? ( app-text/mupdf )
+ perl? ( dev-lang/perl:= )
+ png? ( media-libs/libpng:0= )
+ postscript? ( >=app-text/ghostscript-gpl-9.09[cups] )
+ tiff? ( media-libs/tiff:0 )
+ zeroconf? ( net-dns/avahi[dbus] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-util/gdbus-codegen
+ >=sys-devel/gettext-0.18.3
+ virtual/pkgconfig
+ test? ( media-fonts/dejavu )
+"
+
+src_prepare() {
+ local need_eautoreconf=
+
+ default
+
+ if ! use test ; then
+ eapply "${FILESDIR}"/${PN}-1.28.2-make-missing-testfont-non-fatal.patch
+ need_eautoreconf=yes
+ elif [[ "${PV}" == "9999" ]] ; then
+ need_eautoreconf=yes
+ fi
+
+ [[ -n ${need_eautoreconf} ]] && eautoreconf
+
+ # Bug #626800
+ append-cxxflags -std=c++11
+}
+
+src_configure() {
+ local myeconfargs=(
+ --enable-imagefilters
+ --localstatedir="${EPREFIX}"/var
+ --with-browseremoteprotocols=DNSSD,CUPS
+ --with-cups-rundir="${EPREFIX}"/run/cups
+ --with-fontdir="fonts/conf.avail"
+ --with-pdftops=pdftops
+ --with-rcdir=no
+ --without-php
+ $(use_enable dbus)
+ $(use_enable foomatic)
+ $(use_enable ldap)
+ $(use_enable pclm)
+ $(use_enable pdf mutool)
+ $(use_enable postscript ghostscript)
+ $(use_enable static-libs static)
+ $(use_enable zeroconf avahi)
+ $(use_with jpeg)
+ $(use_with png)
+ $(use_with tiff)
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ default
+
+ if use perl; then
+ pushd "${S}/scripting/perl" > /dev/null
+ perl-module_src_configure
+ perl-module_src_compile
+ popd > /dev/null
+ fi
+}
+
+src_install() {
+ default
+
+ if use perl; then
+ pushd "${S}/scripting/perl" > /dev/null
+ perl-module_src_install
+ perl_delete_localpod
+ popd > /dev/null
+ fi
+
+ if use postscript; then
+ # workaround: some printer drivers still require pstoraster and pstopxl, bug #383831
+ dosym gstoraster /usr/libexec/cups/filter/pstoraster
+ dosym gstopxl /usr/libexec/cups/filter/pstopxl
+ fi
+
+ find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+
+ cp "${FILESDIR}"/cups-browsed.init.d-r1 "${T}"/cups-browsed || die
+
+ if ! use zeroconf ; then
+ sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
+ sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
+ fi
+
+ doinitd "${T}"/cups-browsed
+ systemd_dounit "${S}/utils/cups-browsed.service"
+}
+
+src_test() {
+ emake check
+}
+
+pkg_postinst() {
+ if ! use foomatic ; then
+ ewarn "You are disabling the foomatic code in cups-filters. Please do that ONLY if absolutely."
+ ewarn "necessary. net-print/foomatic-filters as replacement is deprecated and unmaintained."
+ fi
+}