[gentoo-commits] repo/gentoo:master commit in: net-libs/mbedtls/

["Anthony G. Basile" <blueness@gentoo.org>]

commit:     28a471d4c5bbf70a220403206a6a62c0740e0926
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Fri Jan  8 02:13:24 2021 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Fri Jan  8 02:13:24 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28a471d4

net-libs/mbedtls: version bumps to 2.16.9 and 2.25.0, bug #764317

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Anthony G. Basile <blueness <AT> gentoo.org>

 net-libs/mbedtls/Manifest              |  2 +
 net-libs/mbedtls/mbedtls-2.16.9.ebuild | 94 +++++++++++++++++++++++++++++++++
 net-libs/mbedtls/mbedtls-2.25.0.ebuild | 95 ++++++++++++++++++++++++++++++++++
 3 files changed, 191 insertions(+)

diff --git a/net-libs/mbedtls/Manifest b/net-libs/mbedtls/Manifest
index aef009b8f5b..f4394f3b241 100644
--- a/net-libs/mbedtls/Manifest
+++ b/net-libs/mbedtls/Manifest
@@ -1,2 +1,4 @@
 DIST mbedtls-2.16.8.tar.gz 2662927 BLAKE2B 80dabffe644c792ce8a317629950bee71a2376be8f84de29d5cb92047ee433347e7e91be513d638b2954c0c7b2393eaef81b7d449753efffab25694b8a8b52d5 SHA512 645d58d42594a2b547b904634acc1e7e8583465e075c190183e1179638f05e1f8f5c56561ab172fed8dcec4a1742429663abdfdc25d607410ea64a35fbb22168
+DIST mbedtls-2.16.9.tar.gz 2668396 BLAKE2B c637509e8960916bea714b0558b729bf43544d64a560b2e76beba78f8d1355e982f0112bd9e5dd5a14698fa8292d23ed0f41670b220d48d26d6b5a17884481d4 SHA512 f72538851c7a24ac14b5c153220260a49a083bfff44a52e9c1e77c51109bac779b5b4caac21f995176fe8f9d27843f3495692d6c7e9dc733cbcec896823ff0e0
 DIST mbedtls-2.24.0.tar.gz 3912697 BLAKE2B 4355fb4db90e3d72e73adcd8ee96c7db2809154c08a00c1a3a8a8f8d6360689f17317a6dd3564c85e1fadece1a49f1ce30561ad21faf48a5bab78e223f2cd070 SHA512 5437ea57eb8b8af9446a796876aa2bfe3c59c88f926b1638c7e8a021a8bef9f4bc6cb1b254e7387e2afe095bd27c518060719726bbaf5478582a56c34315cfb8
+DIST mbedtls-2.25.0.tar.gz 3994272 BLAKE2B 27a326ba08c341ed47ce280401a4b73606138aa8946fd8d8df5d084496eecc6eadf4eedd65270725a360d4b171c86cefeccb6b1515847587f0f11ed15b7dda9b SHA512 78e68dd9a2939fb9e40d796dcc2de36671c900921eac800688bfc3b5f47fda88be2eb4c7dcb34a01628983cd66323b15606ef2a29e7cbfda0d86aa3f6c948647

diff --git a/net-libs/mbedtls/mbedtls-2.16.9.ebuild b/net-libs/mbedtls/mbedtls-2.16.9.ebuild
new file mode 100644
index 00000000000..324eaa4202f
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.16.9.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/3.12.0" # ffmpeg subslot naming: SONAME tuple of {libmbedcrypto.so,libmbedtls.so,libmbedx509.so}
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs -static-libs test threads zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=$(usex static-libs)
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+	use doc && multilib_is_native_abi && cd "${S}" && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake_src_test
+}
+
+multilib_src_install() {
+	cmake_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}

diff --git a/net-libs/mbedtls/mbedtls-2.25.0.ebuild b/net-libs/mbedtls/mbedtls-2.25.0.ebuild
new file mode 100644
index 00000000000..c1bb84ede01
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.25.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/6.13.1" # ffmpeg subslot naming: SONAME tuple of {libmbedcrypto.so,libmbedtls.so,libmbedx509.so}
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs -static-libs test threads zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=$(usex static-libs)
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
+		-DMBEDTLS_FATAL_WARNINGS=OFF # Don't use -Werror, #744946
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+	use doc && multilib_is_native_abi && cd "${S}" && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake_src_test
+}
+
+multilib_src_install() {
+	cmake_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}