[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog-plugins/

["Matt Turner" <mattst88@gentoo.org>]

commit:     86a0439909d2a50b44d3b6ee64cb28d4e1176132
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  4 18:07:17 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Jan  5 18:29:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86a04399

media-gfx/eog-plugins: Version bump to 3.26.6

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/eog-plugins/Manifest                  |  1 +
 media-gfx/eog-plugins/eog-plugins-3.26.6.ebuild | 64 +++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/media-gfx/eog-plugins/Manifest b/media-gfx/eog-plugins/Manifest
index e7d9b40b9ee..80e1e6f0855 100644
--- a/media-gfx/eog-plugins/Manifest
+++ b/media-gfx/eog-plugins/Manifest
@@ -1 +1,2 @@
 DIST eog-plugins-3.26.5.tar.xz 478188 BLAKE2B 655eb9860435775862ba44bd26530edff778a3c8c574e9bf592800b4d57b4e5b0e52d36b7d71d6a6d615d47c320542105dcee9de89250901fcbfa6c255dcfddc SHA512 3b7979d241c2c0b522ffb6c30a6b8c90fed9e899cda8a73fb9d9a9392f474516f8c24fc75f3f35f920c8a6cf04b8bda611a8669839588936c48467813a6227a7
+DIST eog-plugins-3.26.6.tar.xz 482004 BLAKE2B a70a7d1b69b7d5e6e4d44e79a4305c08ab95c06596512bf458628a65b1a8b5f7fc6c3caf39385ce722de7fdabcf0cc5e620f9dfbc53dfc377fe29252fb21a23c SHA512 67b3cfcc071ef5a196f87041039f65c9ef8e7ba2ef1cdc8dd9ea4d67f64c8b1ee0990446c5cec4fe229aabb35d106a4c0804ba6e8cbd2edfe5a91ddc3765527a

diff --git a/media-gfx/eog-plugins/eog-plugins-3.26.6.ebuild b/media-gfx/eog-plugins/eog-plugins-3.26.6.ebuild
new file mode 100644
index 00000000000..de71bfb1a9b
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-3.26.6.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+exif map picasa +python"
+REQUIRED_USE="
+	map? ( exif )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libpeas-0.7.4:=
+	>=media-gfx/eog-3.15.90
+	>=x11-libs/gtk+-3.14:3
+	exif? ( >=media-libs/libexif-0.6.16 )
+	map? (
+		media-libs/libchamplain:0.12[gtk]
+		>=media-libs/clutter-1.9.4:1.0
+		>=media-libs/clutter-gtk-1.1.2:1.0 )
+	picasa? ( >=dev-libs/libgdata-0.9.1:= )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-libs/glib-2.32:2[dbus]
+		dev-libs/libpeas:=[gtk,python,${PYTHON_SINGLE_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		')
+		gnome-base/gsettings-desktop-schemas
+		media-gfx/eog[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+	use exif && plugins="${plugins},exif-display"
+	use map && plugins="${plugins},map"
+	use picasa && plugins="${plugins},postasa"
+	use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder,maximize-windows"
+	gnome2_src_configure \
+		$(use_enable python) \
+		--with-plugins=${plugins}
+}