[gentoo-commits] repo/gentoo:master commit in: dev-util/clion/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     b0a54399441d793fbb4d06eff9eb7d863056168d
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Mon Jan  4 21:40:22 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Jan  5 08:14:08 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b0a54399

dev-util/clion: remove old version

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/18947
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/clion/clion-2020.3.1.ebuild | 98 ------------------------------------
 1 file changed, 98 deletions(-)

diff --git a/dev-util/clion/clion-2020.3.1.ebuild b/dev-util/clion/clion-2020.3.1.ebuild
deleted file mode 100644
index 6db6b6c93ba..00000000000
--- a/dev-util/clion/clion-2020.3.1.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit desktop wrapper
-
-DESCRIPTION="A complete toolset for C and C++ development"
-HOMEPAGE="https://www.jetbrains.com/clion"
-SRC_URI="https://download.jetbrains.com/cpp/CLion-${PV}.tar.gz"
-
-LICENSE="|| ( IDEA IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )
-	Apache-1.1 Apache-2.0 BSD BSD-2 CC0-1.0 CDDL-1.1 CPL-0.5 CPL-1.0
-	EPL-1.0 EPL-2.0 GPL-2 GPL-2-with-classpath-exception GPL-3 ISC JDOM
-	LGPL-2.1+ LGPL-3 MIT MPL-1.0 MPL-1.1 OFL public-domain PSF-2 UoI-NCSA ZLIB"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-RESTRICT="bindist mirror splitdebug"
-
-BDEPEND="dev-util/patchelf"
-
-# RDEPENDS may cause false positives in repoman.
-# clion requires cmake and gdb at runtime to build and debug C/C++ projects
-RDEPEND="
-	app-accessibility/at-spi2-atk
-	app-accessibility/at-spi2-core
-	dev-libs/atk
-	dev-libs/libdbusmenu
-	dev-libs/nss
-	dev-util/cmake
-	media-libs/alsa-lib
-	media-libs/freetype
-	net-print/cups
-	sys-devel/gdb
-	x11-libs/libXcomposite
-	x11-libs/libXcursor
-	x11-libs/libXi
-	x11-libs/libXScrnSaver
-	x11-libs/libXtst
-	x11-libs/pango"
-
-QA_PREBUILT="opt/${P}/*"
-
-src_prepare() {
-	default
-
-	local remove_me=(
-		bin/gdb/linux
-		bin/lldb/linux
-		bin/cmake
-		license/CMake*
-		lib/pty4j-native/linux/aarch64
-		lib/pty4j-native/linux/mips64el
-		lib/pty4j-native/linux/ppc64le
-	)
-
-	use amd64 || remove_me+=( bin/fsnotifier64 lib/pty4j-native/linux/x86_64)
-	use x86 || remove_me+=( bin/fsnotifier lib/pty4j-native/linux/x86)
-
-	rm -rv "${remove_me[@]}" || die
-
-	for file in "jbr/lib/"/{libjcef.so,jcef_helper}
-	do
-		if [[ -f "${file}" ]]; then
-			patchelf --set-rpath '$ORIGIN' ${file} || die
-		fi
-	done
-}
-
-src_install() {
-	local dir="/opt/${P}"
-
-	insinto "${dir}"
-	doins -r *
-	fperms 755 "${dir}"/bin/{clion.sh,clang/linux/clang{d,-tidy}}
-
-	if use amd64; then
-		fperms 755 "${dir}"/bin/fsnotifier64
-	fi
-	if use arm; then
-		fperms 755 "${dir}"/bin/fsnotifier-arm
-	fi
-	if use x86; then
-		fperms 755 "${dir}"/bin/fsnotifier
-	fi
-
-	if [[ -d jbr ]]; then
-		fperms 755 "${dir}"/jbr/bin/{jaotc,java,javac,jdb,jjs,jrunscript,keytool,pack200,rmid,rmiregistry,serialver,unpack200}
-	fi
-
-	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
-	newicon "bin/${PN}.svg" "${PN}.svg"
-	make_desktop_entry "${PN}" "clion" "${PN}" "Development;IDE;"
-
-	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
-	dodir /usr/lib/sysctl.d/
-	echo "fs.inotify.max_user_watches = 524288" > "${D}/usr/lib/sysctl.d/30-clion-inotify-watches.conf" || die
-}