[gentoo-commits] repo/gentoo:master commit in: sys-process/tini/

["William Hubbs" <williamh@gentoo.org>]

commit:     a770c6979c580d17a912fe16b33a59c2266ddcd8
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  4 22:59:19 2021 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Mon Jan  4 23:06:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a770c697

sys-apps/tini: 0.19.0 bump

Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 sys-process/tini/Manifest           |  1 +
 sys-process/tini/tini-0.19.0.ebuild | 59 +++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/sys-process/tini/Manifest b/sys-process/tini/Manifest
index 0b361120492..e704ce94a15 100644
--- a/sys-process/tini/Manifest
+++ b/sys-process/tini/Manifest
@@ -1 +1,2 @@
 DIST tini-0.18.0.tar.gz 32152 BLAKE2B d676f0f1b4d9f6dca98cdb626aa7c525ec55e090cfeb1cf0e9ab167f1ef4285123223873e92e81d5d62ceb631e26e9012f16b28b1d35813ac801f8e4594be70b SHA512 83279180b6a875aaff9b6b7446ee7e71fd05357279744afcb4db67c76572dc871acfba86c035857009b5dd88ca75d9f2e815d6a925563cdb3e6e771eb83be9b1
+DIST tini-0.19.0.tar.gz 32369 BLAKE2B 5d86f6299b92152063974e6ecd347e1a2ba90f0188f2a702ddb6c814fc1c9723062481fe560caa89e9f74883017ee833566adf1eb1f11fe625671eced47f3296 SHA512 1fa85b56e2c6085ea474f251928e7a40510d92aeef60b3c145b0496969c1b5df86835d143cb91ef5b4bf4da63fa8a56947cc39a4276e4b72faa57276d432b292

diff --git a/sys-process/tini/tini-0.19.0.ebuild b/sys-process/tini/tini-0.19.0.ebuild
new file mode 100644
index 00000000000..4e04e46695c
--- /dev/null
+++ b/sys-process/tini/tini-0.19.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake flag-o-matic
+
+GIT_COMMIT=fec3683b971d9c3ef73f284f176672c44b448662
+DESCRIPTION="A tiny but valid init for containers"
+HOMEPAGE="https://github.com/krallin/tini"
+SRC_URI="https://github.com/krallin/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+args +static"
+
+src_prepare() {
+	cmake_src_prepare
+
+	local sed_args=(
+		# Do not strip binary
+		-e 's/-Wl,-s")$/")/'
+
+		# Remove -Werror and -pedantic-errors in order to allow macro
+		# redefinition, so that CFLAGS="-U_FORTIFY_SOURCE" does not
+		# trigger an error due to add_definitions(-D_FORTIFY_SOURCE=2)
+		# in CMakeLists.txt (bug 626438).
+		-e "s/ -Werror / /"
+		-e "s/ -pedantic-errors / /"
+	)
+
+	sed -i "${sed_args[@]}" \
+		-e "s/git.*status --porcelain.*/true/" \
+		-e "s/git.*log -n 1.*/true/" \
+		-e "s/git.\${tini_VERSION_GIT}/git.${GIT_COMMIT}/" \
+		CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=()
+	use args || mycmakeargs+=(-DMINIMAL=ON)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	append-cflags -DPR_SET_CHILD_SUBREAPER=36 -DPR_GET_CHILD_SUBREAPER=37
+	cmake_src_compile
+}
+
+src_install() {
+	cmake_src_install
+	if use static; then
+		mv "${ED}"/usr/bin/{${PN}-static,${PN}} || die
+	else
+		rm "${ED}"/usr/bin/${PN}-static || die
+	fi
+}