[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     0c828f01ed8a2e8fd2a079b081f7e5bcb056c2e3
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  4 08:51:57 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan  4 09:45:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c828f01

dev-python/django: Bump to 3.1.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |  2 +
 dev-python/django/django-3.1.5.ebuild | 95 +++++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 444e0009847..30c0fd19297 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -8,3 +8,5 @@ DIST Django-3.1.3.checksum.txt 2429 BLAKE2B 7184da75a1da2c615c78a892c8331ff4abfe
 DIST Django-3.1.3.tar.gz 9253273 BLAKE2B 9284b637ea39e028ebabe44de50dacfe6a89621fcc5eea73b7f470fc998faeb361da428be8f3f3e349f25b8629b5a350f3a5b7c35ea50183b285daf63d8944a7 SHA512 0f49316dc61a299a257313c27051852e948337491047bacb2221c9c753a5cf4bafb2ed686311ad5345dd3045260331afccb013c21503891538340225a469d1ad
 DIST Django-3.1.4.checksum.txt 2466 BLAKE2B 635ddd40b542890aef29f53df0fad172e48450081f57c72042a71bb5de654b1d1f5f7ce0c588b1070a203e1d4afe3a1ed19431dd23a2a67cd510d4072c79a00f SHA512 729b771008489bbf0563002e438ef88abb2a14b2c29f307cb2db9c75450f30ac8bd4920bf0493dbec06b3640fc0d4b6817e8a054af1028ad065bd321c761a6c3
 DIST Django-3.1.4.tar.gz 9392125 BLAKE2B b583442de50c358e70a49b9ef557d43211e6faee17933a44012dbb9f0dac3ccbf0a91e01a2b8b798fff7ae05100199e9e9c94a81748b41ea13e49d12bb510617 SHA512 02cfaabb25e5f932dcbf659faba2f0afe298e4bee4f510f7adebfff181bdd13c3a0b08e8ce379bcc59326d904be8699db4ce31065d93566b93cad758365207f5
+DIST Django-3.1.5.checksum.txt 2428 BLAKE2B 69347177b3c8c592a0b9df832c8f0abebdd4f1ff420f95f63310eb41d3614b241dc8f01b71abfec12faa006a8e69310d31cd68425f57ecf7a02948e83c65e0b3 SHA512 93d3e0de057518b60d9da2c1193ec59a8601f53b5d81a09fa4f6866336fbff85b81c01711eb07544fce30fe17e6dec89e5a5d6a66a929d451bca77cfe172bf19
+DIST Django-3.1.5.tar.gz 9257571 BLAKE2B 0ec618753d922e64b2f0e75506843383568c0013a8f7528cf10e9ee49ffc7be8a3effda39c27497510728a16d276db5c620bab22b5a001a86cafdb4d4e2560ea SHA512 b8f0e034fcd282d6e4a9e42565da5d5f4750c900264bed10e72b8c1866370f75fd1bc856d22950e1d3ad03229c38559989a26ccc9f1252ea31d407410134a548

diff --git a/dev-python/django/django-3.1.5.ebuild b/dev-python/django/django-3.1.5.ebuild
new file mode 100644
index 00000000000..240bc31938b
--- /dev/null
+++ b/dev-python/django/django-3.1.5.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/asgiref[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=app-crypt/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Additional Backend support can be enabled via"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	elog
+	elog "Other features can be enhanced by"
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}