[gentoo-commits] repo/gentoo:master commit in: media-video/aravis/

["Sam James" <sam@gentoo.org>]

commit:     1f89e0eb693aa4ea34133efd3a05c1cd6904355e
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Jan  1 03:32:00 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan  1 03:32:00 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f89e0eb

media-video/aravis: bump to 0.8.5

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-video/aravis/Manifest            |  1 +
 media-video/aravis/aravis-0.8.5.ebuild | 69 ++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/media-video/aravis/Manifest b/media-video/aravis/Manifest
index a85fb353063..9cf2ceb0ae5 100644
--- a/media-video/aravis/Manifest
+++ b/media-video/aravis/Manifest
@@ -1 +1,2 @@
 DIST aravis-0.7.2.tar.gz 940928 BLAKE2B 67b6772aaf6195e393caf2f3fcf6d24acace9d7160023c801f93d479e9d488e4082dcd11d40a8db18dea6cd516e0b24cb78e46de09d455a3c822208d9f33af5b SHA512 5cc6c01f77462c595a87a5899df752a5018e72b4de108fc3bcebbb39542482fc535401a7f10732270d98998fe807c929ae9e7750cc7ac0ce089763d1eb148e2a
+DIST aravis-0.8.5.tar.gz 966208 BLAKE2B abeb87911e20898765a41a663a539932cafe65a297ae3887379ca2760132150fde1fb87dbd5f718618b90f5eb2f2fd4941a85ebf7139b0d4ae8a6be458338450 SHA512 2e6ab898be0d1e9a93555bcf83bb447f19c46c5d3c3a8713b9a2174fd165992d5737393f417f6e46504d120d15955dc67e89342449f11356a3fd1e6968ac233e

diff --git a/media-video/aravis/aravis-0.8.5.ebuild b/media-video/aravis/aravis-0.8.5.ebuild
new file mode 100644
index 00000000000..5b917f730ca
--- /dev/null
+++ b/media-video/aravis/aravis-0.8.5.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg
+
+DESCRIPTION="Library for video acquisition using Genicam cameras"
+HOMEPAGE="https://github.com/AravisProject/aravis"
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/AravisProject/${PN}"
+else
+	MY_P="${PN^^}_${PV//./_}"
+	SRC_URI="https://github.com/AravisProject/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2+"
+SLOT="0"
+IUSE="gtk-doc fast-heartbeat gstreamer introspection packet-socket test usb viewer"
+RESTRICT="!test? ( test )"
+
+GST_DEPEND="
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="
+	dev-libs/glib:2[gtk-doc?]
+	dev-libs/libxml2:2
+	sys-libs/zlib
+	gstreamer? ( ${GST_DEPEND} )
+	packet-socket? ( sys-process/audit )
+	usb? ( virtual/libusb:1 )
+	viewer? (
+		${GST_DEPEND}
+		x11-libs/gtk+:3
+		x11-libs/libnotify
+	)
+"
+RDEPEND="${DEPEND}"
+
+if [[ ${PV} != 9999 ]]; then
+	S="${WORKDIR}/${PN}-${MY_P}"
+fi
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gtk-doc documentation)
+		$(meson_use fast-heartbeat)
+		$(meson_feature gstreamer gst-plugin)
+		$(meson_feature introspection)
+		$(meson_feature packet-socket)
+		$(meson_use test tests)
+		$(meson_feature usb)
+		$(meson_feature viewer)
+	)
+	meson_src_configure
+}