[gentoo-commits] repo/proj/guru:master commit in: dev-lang/fbc/

["Andrew Ammerlaan" <andrewammerlaan@riseup.net>]

commit:     0d80101be5b3d381f41973b0be9436cb43972d0c
Author:     William Breathitt Gray <vilhelm.gray <AT> gmail <DOT> com>
AuthorDate: Mon Dec 28 23:10:57 2020 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> riseup <DOT> net>
CommitDate: Mon Dec 28 23:14:01 2020 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=0d80101b

dev-lang/fbc: Add fbc-bootstrap as a BDEPEND

This allows bootstrapping logic to move to the dedicated
dev-lang/fbc-bootstrap package thus simplifying the ebuild.

Signed-off-by: William Breathitt Gray <vilhelm.gray <AT> gmail.com>

 dev-lang/fbc/fbc-1.07.2-r2.ebuild | 61 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/dev-lang/fbc/fbc-1.07.2-r2.ebuild b/dev-lang/fbc/fbc-1.07.2-r2.ebuild
new file mode 100644
index 00000000..2d430eea
--- /dev/null
+++ b/dev-lang/fbc/fbc-1.07.2-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A free/open source, multi-platform BASIC compiler."
+HOMEPAGE="https://www.freebasic.net"
+SRC_URI="https://github.com/freebasic/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="FDL-1.2 GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gpm libffi opengl X"
+
+DEPEND="
+	sys-libs/ncurses:=
+	gpm? ( sys-libs/gpm )
+	libffi? ( dev-libs/libffi )
+	opengl? ( virtual/opengl )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXpm
+		x11-libs/libXrandr
+		x11-libs/libXrender
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="|| (
+		dev-lang/fbc
+		dev-lang/fbc-bootstrap )"
+
+DOCS="${S}/doc/fbc.1"
+
+src_compile() {
+	local xcflags=(
+		$(usex gpm "" "-DDISABLE_GPM")
+		$(usex libffi "" " -DDISABLE_FFI")
+		$(usex opengl "" " -DDISABLE_OPENGL")
+		$(usex X "" " -DDISABLE_X11")
+	)
+
+	local fbc="fbc"
+	local fbcflags=""
+	# fbc requires a space after the -Wl option
+	local fblflags="${LDFLAGS//-Wl,/-Wl }"
+
+	if has_version -b dev-lang/fbc-bootstrap; then
+		fbc="fbc-bootstrap"
+		fbcflags="-prefix ${EPREFIX}/usr/share/freebasic-bootstrap"
+		fblflags+=" -prefix ${EPREFIX}/usr/share/freebasic-bootstrap"
+	fi
+
+	# Build fbc
+	emake CFLAGS="${CFLAGS} ${xcflags[*]} -I/usr/$(get_libdir)/libffi/include" FBC="${fbc}" FBCFLAGS="${fbcflags}" FBLFLAGS="${fblflags}" TARGET="${CHOST}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="/usr" TARGET="${CHOST}" install
+	einstalldocs
+}